Haskell：將「a」限制爲某些類型？

Question

我打算包含在每個節點的元組樹：

-- Should be initialized with `a' as a tuple of (Int, Int) or (Float, Float) 
data MMTree a = Empty | Node a (MMTree a) (MMTree a) deriving Show 

有什麼辦法來限制a，使MMTree可以只與特定類型的初始化;即(Int, Int)或(Float, Float)而不是任何舊類型？

Answer 1

是的。您可以使用廣義代數數據類型（GADT，http://en.wikibooks.org/wiki/Haskell/GADT），這些數據類型正是您所需要的（結果類型取決於所使用的構造函數）。作爲一個簡單的解決方案，可以使一個構造爲每個可能的節點類型：

{-# LANGUAGE GADTs #-} 

data MMTree a where 
    Empty :: MMTree a 
    NodeI :: (Int, Int) -> MMTree (Int, Int) -> MMTree (Int, Int) -> MMTree (Int, Int) 
    NodeF :: (Float, Float) -> MMTree (Float, Float) -> MMTree (Float, Float) -> MMTree (Float, Float) 

但是，這個方案是不是很好（因爲你需要添加更多的構造函數，如果以後你需要使用其他元素使用相同的樹型）。所以，DataKinds和TypeFamilies救援：

{-# LANGUAGE GADTs #-} 
{-# LANGUAGE DataKinds #-} 
{-# LANGUAGE TypeFamilies #-} 

data TreeType 
    = TInt 
    | TFloat 

type family Elem (t :: TreeType) where 
    Elem TInt = (Int, Int) 
    Elem TFloat = (Float, Float) 

data MMTree (t :: TreeType) where 
    Empty :: MMTree a 
    Node :: Elem a -> MMTree a -> MMTree a -> MMTree a 

test1 :: MMTree TInt 
test1 = Node (1, 1) Empty Empty 

test2 :: MMTree TFloat 
test2 = Node (2.0, 3.0) Empty Empty 

這是，如果你真的想在data聲明限制使用的類型的解決方案。不過，我想提出一個更簡單的解決方案：只需保留樹定義，並且如果您想要處理一個樹，其中節點預期包含數值的元組，則只需使用類型簽名來編寫函數：

someFun :: (Num a) => MMTree (a, a) -> r 

Answer 2

如果改爲寫

data MMTree a = Empty | Node (a, a) (MMTree a) (MMTree a) deriving Show 

可以保證節點都將在他們同一類型的元。這不完全是你要求的，但可能是你真正需要的。當然，它簡化了這個問題：現在你只需要將a限制爲Int或Float，而不是它們的元組，如果這真的是你需要的。