分析包含=

Question

的cmdline參數

使用批處理文件多年後，我驚訝地發現等號'='被認爲是參數分隔符。

鑑於這種測試腳本：

echo arg1: %1 
echo arg2: %2 
echo arg3: %3 

和調用：

test.bat a=b c 

輸出爲：

arg1: a 
arg2: b 
arg3: c 

這是爲什麼和如何能避免？我不希望劇本的用戶解釋這個怪癖並引用「a = b」，這是違反直覺的。

此批處理腳本是在Windows 7

=====編輯=====

運行多一點背景：寫一個bat文件時啓動Java我遇到了這個問題應用。我想在bat文件中使用一些參數，然後將剩下的傳給java應用程序。所以我第一次嘗試做shift，然後重建參數列表（因爲%*不受shift的影響）。它看起來是這樣的，這時候我發現了問題：

rem Rebuild the args, %* does not work after shift 
:args 
if not "%1" == "" (
    set ARGS=!ARGS! %1 
    shift 
    goto args 
) 

下一步是不使用轉向了，但通過一次從%*刪除一個字符，直到一個空間，而實現由指針偏移遇到：

rem Remove the 1st arg if it was the profile 
set ARGS=%* 
if not "%FIRST_ARG%" == "%KNOA_PROFILE%" goto remove_first_done 
:remove_first 
if not defined ARGS goto remove_first_done 
if "%ARGS:~0,1%" == " " goto remove_first_done 
set ARGS=%ARGS:~1% 
goto remove_first 
:remove_first_done 

但這是醜陋的，在某些情況下，我可能還沒有考慮失敗。所以最後我決定編寫一個Java程序來處理參數解析！在我的情況下，這很好，因爲我啓動了一個服務器，額外的Java調用的懲罰是最小的。令人難以置信的是，有時你最終會做什麼。

您可能想知道爲什麼我沒有照顧Java應用程序本身的參數？答案是我希望能夠傳遞像-Xmx這樣的JVM選項，這些選項在調用java之前必須被處理。

Answer 1

我猜它這是否讓/param=data相同/param data

我不知道任何技巧來解決這個愚蠢的（可能是由設計）解析的問題，但我能拿出一個超級難看的解決方法：

@echo off 
setlocal ENABLEEXTENSIONS 
set param=1 
:fixnextparam 
set p= 
((echo "%~1"|find " ")>nul)||(
    call :fixparam %param% "%~1" "%~2" %* 2>nul 
) 
if "%p%"=="" (set "p%param%=%1") else shift 
shift&set /A param=%param% + 1 
if not "%~1"=="" goto fixnextparam 

echo.1=%p1% 
echo.2=%p2% 
echo.3=%p3% 
echo.4=%p4% 
echo.5=%p5% 
goto:EOF 


:fixparam 
set p%1= 
for /F "tokens=4" %%A in ("%*") do (
    if "%%~A"=="%~2=%~3" set p=!&set "p%1=%%A" 
) 
goto:EOF 

當我執行test.cmd foo=bar baz "fizz buzz" w00t我得到：

1=foo=bar 
2=baz 
3="fizz buzz" 
4=w00t 
5= 

的問題，這當然是ÿ你不能做％〜dp1風格的變量擴展。 不可能做call :mylabel %*，然後使用％1，因爲call：batchlabel具有相同的參數解析問題！

如果你真的需要％〜DP1處理您可以使用WSH/batch hybrid黑客：

@if (1==1) @if(1==0) @ELSE 
@echo off 
@SETLOCAL ENABLEEXTENSIONS 
if "%SPECIALPARSE%"=="*%~f0" (
    echo.1=%~1 
    echo.2=%~2 
    echo.3=%~3 
    echo.4=%~4 
    echo.5=%~5 
) else (
    set "SPECIALPARSE=*%~f0" 
    cscript //E:JScript //nologo "%~f0" %* 
) 
@goto :EOF 
@end @ELSE 
w=WScript,wa=w.Arguments,al=wa.length,Sh=w.CreateObject("WScript.Shell"),p=""; 
for(i=0;i<al;++i)p+="\""+wa.Item(i)+"\" "; 
function PipeStream(i,o){for(;!i.AtEndOfStream;)o.Write(i.Read(1))} 
function Exec(cmd,e){ 
    try{ 
     e=Sh.Exec(cmd); 
     while(e.Status==0){ 
      w.Sleep(99); 
      PipeStream(e.StdOut,w.StdOut); 
      PipeStream(e.StdErr,w.StdErr); 
     } 
     return e.ExitCode; 
    }catch(e){return e.number;} 
} 
w.Quit(Exec("\""+WScript.ScriptFullName+"\" "+p)); 
@end 

Answer 2

我只回答這個：>>這是爲什麼和如何能避免？

我的建議：使用更好的語言。不，我不是在開玩笑。批處理有太多的怪癖/細微差別，加上很多其他的侷限性，但它不值得花時間提出醜陋/低效率的解決方法。如果您運行的是Windows 7或更高版本，那麼爲什麼不嘗試使用vbscript甚至是powershell。這些工具/語言將極大地幫助您完成日常編程/管理任務。作爲VBScript中如何propely採取這樣一個問題護理的例子：

For i=0 To WScript.Arguments.Count-1 
    WScript.Echo WScript.Arguments(i) 
Next 

輸出：

C:\test>cscript //nologo myscript.vbs a=b c 
a=b 
c 

注意，它需要正確的論據照顧。

Answer 3

@echo off 
setlocal enabledelayedexpansion 

if %1 neq ~ (
set "n=%*" 
for %%a in ("!n: =" "!") do (
set "s=%%a" 
if !s:~0^,2!==^"^" (
    set "s=!s:" "= !" 
    set "s=!s:""="!" 
) 
set "m=!m! !s!" 
) 
%0 ~ !m! 
) 
endlocal 
shift 

echo arg1: %~1 
echo arg1: %~2 
echo arg1: %~dp3 
exit /b 

---

c:> untested.bat a=b c "%USERPROFILE%" 

Answer 4

@jeb：這裏的另一種方法

untested.cmd

@echo off 
setlocal enabledelayedexpansion 

set "param=%*" 
set param="%param: =" "%" 

for /f "delims=" %%a in ('echo %param: =^&echo.%') do (
    set "str=%%a" 
    if !str:~0^,2!==^"^" (
    set "str=!str:^&echo.=!" 
    set "str=!str:"^"= !" 
    set str="!str:~1,-1!" 
) 
    set "m=!m! !str!" 
) 

Call :sub %m% 
endlocal & goto :eof 

:sub 
echo arg1: %~1 
echo arg2: %~2 
echo arg3: %~3 
echo arg4: %~4 
goto :eof 

Answer 5

同樣，我無法解釋的異常行爲，但有一個很簡單的解決方案

test.bat的腳本：

echo arg1: %~1 
echo arg2: %~2 
echo arg3: %~3 

調用：

test.bat "a=b" c 

輸出：

arg1: a=b 
arg2: c 
arg3: 

注意只要改變你的論點引用，那麼這樣調用時，引用參數使用波形符號（〜）引用參數會從參數中刪除前導/尾隨引號。