如何關閉在vim窗口中未顯示的所有緩衝區？

Question

我在vim中打開了一大堆緩衝區，只有其中的幾個在分割窗口或其他選項卡中打開。有沒有辦法關閉除了當前可見的分割或製表符之外的所有分支？

Answer 1

這裏有一個替代的解決方案，你可以在你的.vimrc下降：

function! Wipeout() 
    " list of *all* buffer numbers 
    let l:buffers = range(1, bufnr('$')) 

    " what tab page are we in? 
    let l:currentTab = tabpagenr() 
    try 
    " go through all tab pages 
    let l:tab = 0 
    while l:tab < tabpagenr('$') 
     let l:tab += 1 

     " go through all windows 
     let l:win = 0 
     while l:win < winnr('$') 
     let l:win += 1 
     " whatever buffer is in this window in this tab, remove it from 
     " l:buffers list 
     let l:thisbuf = winbufnr(l:win) 
     call remove(l:buffers, index(l:buffers, l:thisbuf)) 
     endwhile 
    endwhile 

    " if there are any buffers left, delete them 
    if len(l:buffers) 
     execute 'bwipeout' join(l:buffers) 
    endif 
    finally 
    " go back to our original tab page 
    execute 'tabnext' l:currentTab 
    endtry 
endfunction 

使用:call Wipeout()。

Answer 2

添加到您的.vimrc：

function! CloseHiddenBuffers() 
    let i = 0 
    let n = bufnr('$') 
    while i < n 
    let i = i + 1 
    if bufloaded(i) && bufwinnr(i) < 0 
     exe 'bd ' . i 
    endif 
    endwhile 
endfun 

然後你就可以做到這一點，收隱藏的緩衝區：

:call CloseHiddenBuffers() 

（您可能需要綁定一個鍵或給它的命令。）

更新：

這裏」該版本已更新爲支持標籤頁。 （我自己並沒有使用標籤頁，所以我沒有意識到bufwinnr只適用於當前頁面上的窗口）。

function! CloseHiddenBuffers() 
    " figure out which buffers are visible in any tab 
    let visible = {} 
    for t in range(1, tabpagenr('$')) 
    for b in tabpagebuflist(t) 
     let visible[b] = 1 
    endfor 
    endfor 
    " close any buffer that's loaded and not visible 
    for b in range(1, bufnr('$')) 
    if bufloaded(b) && !has_key(visible, b) 
     exe 'bd ' . b 
    endif 
    endfor 
endfun 

Answer 3

我知道爲什麼第二個腳本無法正常工作。

這是由於bufloaded（）函數必須是bufexits（）！

的確，要刪除的緩衝區沒有加載！只要刪除這個條件是可以的，但是當我們試圖清除一個未使用的緩衝區時它會發出警告，所以我們必須使用bufexists（b）。

最終的解決方案是：

function! CloseHiddenBuffers() 
    " Tableau pour memoriser la visibilite des buffers                      
    let visible = {} 
    " Pour chaque onglet... 
    for t in range(1, tabpagenr('$')) 
     " Et pour chacune de ses fenetres... 
     for b in tabpagebuflist(t) 
      " On indique que le buffer est visible. 
      let visible[b] = 1 
     endfor 
    endfor 
    " Pour chaque numero de buffer possible... 
    for b in range(1, bufnr('$')) 
     " Si b est un numero de buffer valide et qu'il n'est pas visible, on le 
     " supprime. 
     if bufexists(b) && !has_key(visible, b) 
      " On ferme donc tous les buffers qui ne valent pas 1 dans le tableau et qui 
      " sont pourtant charges en memoire. 
      execute 'bwipeout' b 
     endif 
    endfor 
endfun 

謝謝你。

Answer 4

還有另外一件事情。使用Vim給出的示例幫助tabpagebuflist()獲取出現在選項卡或窗口中的緩衝區列表。我有以下我.vimrc

function! DeleteInactiveBufs() 
    "From tabpagebuflist() help, get a list of all buffers in all tabs 
    let tablist = [] 
    for i in range(tabpagenr('$')) 
     call extend(tablist, tabpagebuflist(i + 1)) 
    endfor 

    "Below originally inspired by Hara Krishna Dara and Keith Roberts 
    "http://tech.groups.yahoo.com/group/vim/message/56425 
    let nWipeouts = 0 
    for i in range(1, bufnr('$')) 
     if bufexists(i) && !getbufvar(i,"&mod") && index(tablist, i) == -1 
     "bufno exists AND isn't modified AND isn't in the list of buffers open in windows and tabs 
      silent exec 'bwipeout' i 
      let nWipeouts = nWipeouts + 1 
     endif 
    endfor 
    echomsg nWipeouts . ' buffer(s) wiped out' 
endfunction 
command! Bdi :call DeleteInactiveBufs() 

Answer 5

有一個插件認爲正是這一點，多一點！

退房close-buffers.vim