如何調用祖父母的構造函數（因爲父母的構造函數沒有定義）？

Question

我認爲，規範的方法來調用父類的構造函數中Perl是：

package Child; 
our @ISA = 'Parent'; 

sub new { 
    my $class = shift; 
    my @args = @_; 
    my $self = $class->SUPER::new(@args); 
    return $self; 
} 

然而，這種結構似乎並沒有工作，如果Parent沒有明確地定義一個new功能（但Grandparent一樣） 。

這種情況，例如，Net::FTP::File。

tq84_ftp.pm：

package tq84_ftp; 

use warnings; 
use strict; 

our @ISA = qw(Net::FTP::File); 

sub new { 
    my $class = shift; 
    my $self = $class->SUPER::new('localhost') 
    or die($@); 
    return $self; 
}  

1; 

script.pl：

use tq84_ftp; 
tq84_ftp->new(); 

輸出：

Can't locate package Net::FTP::File for @tq84_ftp::ISA at tq84_ftp.pm line 10. 
Can't locate package Net::FTP::File for @tq84_ftp::ISA at tq84_ftp.pm line 10. 
Can't locate object method "new" via package "tq84_ftp" at tq84_ftp.pm line 10. 

如何指定我想要Perl找到正確的（這裏：grantparent的）new功能？

Answer 1

看來你認爲Net::FTP::File是Net::FTP一個子類，因此

my $self = $class->SUPER::new('localhost') ... 

應該調用Net::FTP的new方法。

然而，事實上，Net::FTP::File不從Net::FTP沒有繼承。相反，它重新定義了Net::FTP中的一些方法。因此，如果您的課程從Net::FTP::File繼承，則它不會是Net::FTP的孩子。

如果您查看source code for Net::FTP，您可以輕鬆看到這一點。需要注意的是，沒有use base 'Net::FTP'或use parent 'Net::FTP'或低於our @ISA = qw(Net::FTP)：

package Net::FTP::File; 

use strict; 
use warnings; 
use Net::FTP; 

# ... 

sub Net::FTP::pretty_dir { 
    shift; 
    my $newp = shift; 
    if (defined $newp) { 
     $pretty = $newp; 
     $DirProcHash{cols} = $cols{pretty} if $pretty; 
     $DirProcHash{cols} = $cols{utility} if !$pretty; 
    } 
    return $pretty; 
} 

# ... 

sub Net::FTP::isfile { 
    my $ftp = shift; 
    return 1 if $ftp->exists(@_) && !$ftp->isdir(@_); 
    0; 
} 

等等等等

Answer 2

然而，這種結構似乎並沒有工作，如果Parent沒有明確地定義一個新的功能（但Grandparent一樣）。

不正確。

$ perl -E' 
    package Grandparent { 
     sub new { CORE::say(__PACKAGE__) } 
    } 

    package Parent { 
     our @ISA = "Grandparent"; 
    } 

    package Child { 
     our @ISA = "Parent"; 
     sub new { my $class = shift; $class->SUPER::new(); } 
    } 

    Child->new(); 
' 
Grandparent 

---

Can't locate package Net::FTP::File

這當您試圖從尚未聲明一個類繼承獲得的警告。具體來說，您正嘗試使用Net :: FTP :: File而不加載它。

替換

our @ISA = 'Net::FTP::File'; 

與

use Net::FTP::File qw(); 
our @ISA = 'Net::FTP::File'; 

或

use parent 'Net::FTP::File'; 

---

Can't locate object method "new" via package "tq84_ftp"

此消息是有點不清楚，但這樣的事實：Net::FTP::File->new不存在的到期。 Net :: FTP :: File不是一個類，更不用說Net :: FTP的子類。它沒有辦法，更不用說new方法。從Net :: FTP :: File繼承是沒有意義的。

你似乎想創建一個網:: FTP對象，所以更換

use parent 'Net::FTP::File'; 

與

use parent 'Net::FTP'; 

---

最後，你要加載的Net :: FTP文件::它添加到Net :: FTP對象（包括從Net :: FTP繼承的類的對象）的方法。要做到這一點，只需添加

use Net::FTP::File qw();