複製到沒有剪貼板的動態範圍

Question

我試圖在不使用剪貼板的情況下將值粘貼到不同工作表上的動態範圍。當代碼到達Range = Range部分時，它會錯誤地指出「應用程序定義或對象定義的錯誤」。有任何想法嗎？

Sub Test2() 
Dim Start As Worksheet 
Dim ED As Worksheet 
Dim r As Integer, c As Integer, r1 As Integer, c1 As Integer 

Set Start = Sheets("Start") 
Set ED = Sheets("End") 

r = 1 
c = ActiveSheet.UsedRange.Columns.Count 



With Start 
    Do Until .Cells(r, c).Value = "" 
     r = r + 1 

    Loop 
    r = r - 1 

End With 
r1 = 1 
c1 = ActiveSheet.UsedRange.Columns.Count 

With ED 

    Do Until .Cells(r1, c1).Value = "" 
     r1 = r1 + 1 

    Loop 
    r1 = r1 

Range(Cells(r1, 1), Cells(r1 + r - 1, c1)) = Start.Range(Cells(r, c), Cells(1, 1)) 

Start.Activate 

Answer 1

1. ALWAYS每一個家長有資格每Range對象。該範圍（）內的Cells()需要在同一母公司必須指出：

Start.Range(Start.Cells(r, c), Start.Cells(1, 1))

我們不需要循環，而且可以使用END()來找到最後的列和行。

替換：

Do Until .Cells(r, c).Value = "" 
    r = r + 1 

Loop 
r = r - 1 

隨着：

c = .Cells(1, .Columns.Count).End(xlToLeft).Column 
r = .Cells(.Rows.Count, c).End(xlUp).Row 

使用調整大小，它是較短的，更易於維護：

.Cells(r1+1, 1).Resize(r, c).Value = Start.Cells(1, 1).Resize(r, c).Value

所以：

Sub Test2() 
Dim Start As Worksheet 
Dim ED As Worksheet 
Dim r As Long, c As Long, r1 As Long, c1 As Long 

Set Start = Sheets("Start") 
Set ED = Sheets("End") 

With Start 
    c = .Cells(1, .Columns.Count).End(xlToLeft).Column 
    r = .Cells(.Rows.Count, c).End(xlUp).Row 
End With 
With ED 
    c1 = .Cells(1, .Columns.Count).End(xlToLeft).Column 
    r1 = .Cells(.Rows.Count, c1).End(xlUp).Row 
    .Cells(r1+1, 1).Resize(r, c).Value = Start.Cells(1, 1).Resize(r, c).Value 
End With