表中的序言點

Question

我有一個給定的列表，表示一個二維列表x。此表包含的1兩「點」，你可以在下面的例子中看到：

xxxxxxxxxxxxxxxx 
xx1111xxxx111xxx 
xxx1111xxxx11xxx 
x1111xxxxxx111xx 

我只需要1第二點更改爲2如下面的例子：

xxxxxxxxxxxxxxxx 
xx1111xxxx222xxx 
xxx1111xxxx22xxx 
x1111xxxxxx222xx 

我需要一個叫做separate(L,M)謂詞會第一時間列表L，並會產生第二個圖表M

這將是極好的，如果我們能夠解決這個問題，而無需使用任何標準謂詞喜歡「的findall」等等......

Answer 1

您可以使用定義語句語法（DCG）來實現有限狀態轉換器。雖然DCG在生產方面沒有提供太多的組合操作，但它們在實現識別方面非常出色。

所以你想要認識到的是兩種不同類型的1的運行。所以基本上我猜的輸入線看起來在如下擴展巴科斯範式（EBNF）：

line :== exs run1 exs run2 exs | exs. 
exs :== { "x" } "x". 
run1 :== { "1" } "1". 
run2 :== { "1" } "1". 

對於識別問題，你可以寫一個DCG無屬性（接下來就是Prolog的文字，你可以把一個文件或直接通過諮詢一下吧 - [用戶]）：

line --> exs, run1, exs, run2, exs | exs. 

run1 --> "1", run1. 
run1 --> "1". 

run2 --> "1", run2. 
run2 --> "1". 

exs --> "x", exs. 
exs --> "x". 

下面是一些例子運行：

?- phrase(line,"xxx"). 
Yes 
?- phrase(line,"xxx111xxx111xxx"). 
Yes 
?- phrase(line,"xxx111xxx"). 
No 

對於生產問題，你只可以將屬性添加到DCG。使用 差異列表最簡單的工作：

line(I,O) --> exs(I,H), run1(H,J), exs(J,K), run2(K,L), exs(L,O) | exs(I,O). 

run1([0'1|I],O) --> "1", run1(I,O). 
run1([0'1|H],H) --> "1". 

run2([0'2|I],O) --> "1", run2(I,O). 
run2([0'2|H],H) --> "1". 

exs([0'x|I],O) --> "x", exs(I,O). 
exs([0'x|H],H) --> "x". 

下面是一些例子運行：

?- phrase(line(R,[]),"xxx"). 
R = [120, 120, 120] 
?- phrase(line(R,[]),"xxx111xxx111xxx"). 
R = [120, 120, 120, 49, 49, 49, 120, 120, 120, 50, 50, 50, 120, 120, 120] 
?- phrase(line(R,[]),"xxx111xxx"). 
No 

注：0' 是Prolog的符號的字符代碼。在ascii中，我們有0'x = 120,0'1 = 49,0'2 = 50，這說明了結果。以上應該在大多數Prolog系統上運行，因爲它們支持DCG。

再見

定條款語法
http://en.wikipedia.org/wiki/Definite_clause_grammar

有限狀態傳感器
http://en.wikipedia.org/wiki/Finite_state_transducer

Answer 2

我們可以申請臨時音譯（只爲 '水平' 列表）：

transliteration(Matrix, Translit) :- 
    maplist(transliteration(not_seen), Matrix, Translit). 

transliteration(_State, [], []). 
transliteration(State, [X|Xs], [Y|Ys]) :- 
    transliteration(State, X, NewState, Y), 
    transliteration(NewState, Xs, Ys). 

% handle only required state change 
transliteration(not_seen, 0'1, seen_first, 0'1). 
transliteration(seen_first, C, seen_last, C) :- C =\= 0'1. 
transliteration(seen_last, 0'1, seen_last, 0'2). 
% catch all, when no change required 
transliteration(State, C, State, C). 

Answer 3

與sol類似@chac建議使用，但更直接。

walk(L, R) :- walk(s0, L, R). 
walk(_, [], []). % finish 
walk(s0, [0'1|T], [0'1|R]) :- walk(s1, T, R). 
walk(s1, [0'x|T], [0'x|R]) :- walk(s2, T, R). 
walk(s2, [0'1|T], [0'2|R]) :- walk(s2, T, R). 
walk(S, [H|T], [H|R]) :- walk(S, T, R). % keep state and do nothing