動態範圍內的VBA範圍值

Question

我試圖使範圍值「粘貼」而不使用複製/粘貼功能。我對VBA相當陌生，不明白爲什麼我的代碼不起作用。對不起，如果這是一種已經回答的問題，但我無法通過其他帖子找出問題。

我能選擇我想我的價值觀中複製並粘貼過與

name_task = [code].select 
name_task_2 = [code].select 

的範圍，但我不能寫值與

name_task_2 = name_task.value 

這工作name_task_2，對於我來說，我寫了一些相同的東西，但是因爲它不起作用，所以它顯然不一樣：D

sht2.Range("C2:D12") = sht1.Range("A8:B18").value 

Excel sheet1

Sub Time_Estimate() 

Application.ScreenUpdating = False 

Dim name_task As Variant 
Dim name_task_2 As Variant 

Dim R_count As Double 
Dim C_count As Double 

Dim sht1 As Worksheet 
Dim sht2 As Worksheet 

Set sht1 = Sheet1 'Sheets("Tekla_2016") 

name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 
R_count = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)).Rows.Count 
'Debug.Print name_task.Rows.Count 
'Debug.Print name_task.Columns.Count 
Debug.Print R_count 

Set sht2 = Sheet2 'Sheets("Timeforbruk_2016 - UFERDIG") 

name_task_2 = sht2.Range("C2:D2", sht2.Range("C2:D2").Offset(R_count - 1, 0)) 

'name_task_2 = name_task.value 'Why doesn't this work??? 

'sht2.Range("C2:D12") = sht1.Range("A8:B18").value 'This works but it's not dynamic 


Application.ScreenUpdating = True 

End Sub 

編輯： 此代碼現在的工作，因爲我想：

Sub Time_Estimate() 

Application.ScreenUpdating = False 

Dim name_task As Range 
Dim name_task_2 As Range 
Dim rng_sht1 As Range 
Dim rng_sht2 As Range 


Dim R_count As Double 
Dim C_count As Double 

Dim sht1 As Worksheet 
Dim sht2 As Worksheet 

Set sht1 = Sheet1 'Sheets("Tekla_2016") 
Set sht2 = Sheet2 'Sheets("Timeforbruk_2016 - UFERDIG") 

Set name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 
R_count = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)).Rows.Count 

Set name_task_2 = sht2.Range("C2:D2", sht2.Range("C2:D2").Offset(R_count - 1, 0)) 
name_task_2 = name_task.value 

Application.ScreenUpdating = True 

End Sub 

Answer 1

someRange.Select 

選擇範圍someRange並返回布爾值True（你通常不會注意到，因爲你不要試圖將它分配給某些東西）。這意味着，後

name_task = [code].select 
name_task_2 = [code].select 

既name_task和name_task_2是布爾值（True），而不是範圍。

在你發佈你的子有另一個問題：

name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 

因爲你沒有指定name_task是（除Variant，這基本上意味着什麼）什麼，VBA將使用範圍的Value爲默認屬性和name_task將是包含sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)).Value的變體陣列。要指定一個範圍對象你需要使用Set：

Set name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 

從MSDN/this answer：

設定關鍵字。在VBA中，Set關鍵字對於區分對象的分配和對象的默認屬性的分配是必要的。由於Visual Basic .NET不支持默認屬性，因此不需要Set關鍵字，因此不再支持。

這實際上是一個很好的例子，爲什麼使用Option Explicit（或者在你的情況下正確地聲明變量）是一個好主意。如果您聲明Dim name_task As Range VBA會告訴您在正確的線路上出現問題，故障排除變得更加容易。