如何在數據庫中搜索文本字符串？

Question

是否有任何方法來搜索整個SQL Server數據庫的文本字符串？

通過整個數據庫我的意思是表，視圖，存儲過程等

Answer 1

我得到的溶液，以顯示/搜索所有的表，列和SP與存儲過程：

CREATE PROC SearchAllTables 
(
@SearchStr nvarchar(100) 
) 
AS 
BEGIN 

-- Copyright © 2013 Peter Nold. All rights reserved. 
-- Purpose: To search all columns of all tables for a given search string 

CREATE TABLE #Results (ColumnName nvarchar(370), ColumnValue nvarchar(3630)) 

SET NOCOUNT ON 

DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110), @myCount varchar(255) 
SET @TableName = '' 
SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''') 

/* debug */ 
print '************************************************************' 
print 'Starting Search For: ' + @SearchStr2 
print '************************************************************' 

WHILE @TableName IS NOT NULL 
BEGIN 
    SET @ColumnName = '' 
    SET @TableName = 
    (
     SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)) 
     FROM INFORMATION_SCHEMA.TABLES 
     WHERE  TABLE_TYPE = 'BASE TABLE' 
      AND QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName 
      AND OBJECTPROPERTY(
        OBJECT_ID(
         QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) 
         ), 'IsMSShipped' 
          ) = 0 
    ) 

    WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL) 
    BEGIN 
     SET @ColumnName = 
     (
      SELECT MIN(QUOTENAME(COLUMN_NAME)) 
      FROM INFORMATION_SCHEMA.COLUMNS 
      WHERE  TABLE_SCHEMA = PARSENAME(@TableName, 2) 
       AND TABLE_NAME = PARSENAME(@TableName, 1)     
       AND QUOTENAME(COLUMN_NAME) > @ColumnName 
     ) 

     IF @ColumnName IS NOT NULL 
     BEGIN 

      -- debug 
      print 'Searching the field: ' + @TableName + '.' + @ColumnName 

      INSERT INTO #Results 
      EXEC 
      (
       'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(CONVERT(varchar(max), ' + @ColumnName + '), 3630) 
       FROM ' + @TableName + ' (NOLOCK) ' + 
       ' WHERE CONVERT(varchar(max), ' + @ColumnName + ') LIKE ' + @SearchStr2 
      ) 
     END 
    END 
END 

SELECT ColumnName, ColumnValue FROM #Results 

SET @myCount = 'Found in #columns: ' + cast((select count(*) from #Results) AS VARCHAR) 
print '************************************************************' 
print @myCount 
print '************************************************************' 

END 

/* example to search for the text METZ: 
*** 
exec SearchAllTables 'METZ' 
*/ 

Answer 2

如果數據庫您真的意味着絕對的一切，包括程序源代碼，最簡單的將可能是生成一個數據庫轉儲並搜索結果文件中的字符串。這比在信息模式上運行各種查詢要簡單。

Answer 3

這裏是搜索特定文本中存儲的過程的代碼

SELECT Distinct SO.Name 
FROM sysobjects SO (NOLOCK) 
INNER JOIN syscomments SC (NOLOCK) on SO.Id = SC.ID 
AND SO.Type = 'P' 
AND SC.Text LIKE '%test%' 
ORDER BY SO.Name