Word 2007 VBA - 編寫一些文本BOLD和其他ITALIC

Question

我有以下代碼從Excel單元格中選擇數據&取代了我的Word文檔中的一段特定文本（就這個問題而言，Excel單元格已被替換由純文本字符串）。

數據「：去」是恆定的，那麼數據「aaa bbb」可以是任何東西，直到我們到達「也」是恆定的。那麼在「之後」，「ccc ddd eee」之後的數據可以是任何東西，直到它碰到也是恆定的「 - 」。

是否有可能使 「AAA BBB」 數據BOLD &大寫，而使得 「CCC DDD EEE」 數據爲斜體？

「：去AAA BBB CCC的 DDD EEE - 」

Selection.HomeKey Unit:=wdStory 
Selection.Find.ClearFormatting 
Selection.Find.Replacement.ClearFormatting 
With Selection.Find 
    .Text = "MOTMDIV1" 
    .Replacement.Text = ": goes to aaa bbb of ccc ddd eee - " 
    .Forward = True 
    .Wrap = wdFindContinue 
    .Format = False 
    .MatchCase = True 
    .MatchWholeWord = False 
    .MatchWildcards = False 
    .MatchSoundsLike = False 
    .MatchAllWordForms = False 
End With 

Selection.Find.Execute Replace:=wdReplaceAll 

Answer 1

如果你改變你的查找和替換單一查找和全部替換，Word將突出替換文本允許你可以改變被替換範圍的屬性。我已經修改了你的代碼中強調這一點：

Sub ReplaceAndFormat() 
    Dim sConst1 As String, sConst2 As String, sReplaceMent As String 
    Dim rRange As Range, rFormat As Range 

    'Set your constants. This is where you can read in from Excel or whereever 
    sConst1 = "aaa bbb" 
    sConst2 = "ccc ddd eee" 

    'Build the replacement string 
    sReplaceMent = ": goes to " & sConst1 & " of " & sConst2 & " - " 

    'Your replacement code 
    Selection.HomeKey Unit:=wdStory 
    Selection.Find.ClearFormatting 
    Selection.Find.Replacement.ClearFormatting 
    With Selection.Find 
     .Text = "MOTMDIV1" 
     .Replacement.Text = sReplaceMent 
     .Forward = True 
     .Wrap = wdFindContinue 
     .Format = False 
     .MatchCase = True 
     .MatchWholeWord = False 
     .MatchWildcards = False 
     .MatchSoundsLike = False 
     .MatchAllWordForms = False 
     .Execute Replace:=wdReplaceOne 

     'If we replace one by one Word will select the range after it finds it 
     If .Found Then 
      'After you've done the replacement, set it to a range so you can format 
      Set rRange = Selection.Range 

      'We know the length of all the strings so we can set the range of the "aaa bbb" etc etc 
      Set rFormat = ActiveDocument.Range(rRange.Start + 10, rRange.Start + 10 + VBA.Len(sConst1)) 
      'Set the formats for the first part 
      rFormat.Font.Bold = True 
      rFormat.Font.AllCaps = True 

      'Repeat for the second part 
      Set rFormat = ActiveDocument.Range(rRange.Start + 14 + VBA.Len(sConst1), rRange.Start + 14 + VBA.Len(sConst1) + VBA.Len(sConst2)) 
      rFormat.Font.Italic = True 
     End If 
    End With 
End Sub 

注：Repeating Microsoft Word VBA until no search results found