數組操作，並將它們組

Question

我有兩個陣列

id_array :{2 1 1 2 3 1 2} 
type_array :{apple apple orange orange pineapple pineapple pineapple} 

我要處理的上述陣列和基於我想組以下的ID和類型，如下所示：

蘋果2 apple 1 orange 1 2 菠蘿3 菠蘿1 2

Answer 1

這是非常平行於acheong87的答案，但我會用一本字典的數據結構

set types {apple apple orange orange pineapple pineapple pineapple} 
set ids {2 1 1 2 3 1 2} 

set groups [dict create] 
foreach id $ids type $types { 
    dict lappend groups $type [list $id $type] 
} 
puts $groups 
# apple {{2 apple} {1 apple}} orange {{1 orange} {2 orange}} pineapple {{3 pineapple} {1 pineapple} {2 pineapple}} 

set out [list] 
dict for {type sublist} $groups {lappend out $sublist} 
puts out 
# {{2 apple} {1 apple}} {{1 orange} {2 orange}} {{3 pineapple} {1 pineapple} {2 pineapple}} 

---

更新因要求說明：

set ids {2 1 1 2 3 1 2} 
set types {apple apple orange orange pineapple pineapple pineapple} 
set groups [list] 
set current_type "" 
set prev_id -1 
foreach id $ids type $types { 
    if {$type ne $current_type || $id < $prev_id} { 
     if {[info exists group]} {lappend groups $group} 
     set group [list] 
     set current_type $type 
    } 
    lappend group [list $id $type] 
    set prev_id $id 
} 
lappend groups $group 
puts [list $groups] 

相比，你問的這個輸出

{{{2 apple}} {{1 apple}} {{1 orange} {2 orange}} {{3 pineapple}} {{1 pineapple} {2 pineapple}}} 

注意額外的支撐。最終列表$groups是列表的列表。每個元素（或「子列表」）保持一致的結構。我們看到：

• 與含有列表1個元素{2蘋果}的列表，
• 與含有列表1個元素{1個蘋果}的列表，
• 與含有列表{2個元素的列表1 orange}和列表{2 orange}，
• 一個包含列表{1 pineapple}的元素的列表，以及
• 列出了包含列表{2菠蘿}和列表{2 pineapple} 。報告這個最終名單

一種方法是：

foreach sublist $groups { 
    foreach pair $sublist { 
     lassign $pair id type 
     puts "$id -> $type" 
    } 
} 

印刷

2 -> apple 
1 -> apple 
1 -> orange 
2 -> orange 
3 -> pineapple 
1 -> pineapple 
2 -> pineapple 

---

回答最後一個請求：給定上述最終名單：

set answer [list] 
foreach sublist $groups { 
    lappend answer [lindex $sublist 0 1] 
    foreach pair $sublist {lappend answer [lindex $pair 0]} 
} 
puts [join $answer] 

打印

apple 2 apple 1 orange 1 2 pineapple 3 pineapple 1 2 

Answer 2

歡迎來到Stack Overflow。通常，我們喜歡看到用戶嘗試解決他們自己的問題，因爲它有助於將注意力集中到特定的含糊或誤解，未來的訪問者可能會發現有用。然而，我們通常也願意提供幫助，無論如何：

Tcl有一個有趣的形式foreach，它允許我們同時迭代多個列表。

set id_array [list 2 1 1 2 3 1 2] 
set type_array [list apple apple orange orange pineapple pineapple pineapple] 
foreach id $id_array type $type_array { 
    lappend hash($type) [list $id $type] 
} 
foreach name [array names hash] { 
    lappend output $hash($name) 
} 
puts $output 

這種輸出，對我來說，

{{1 orange} {2 orange}} {{3 pineapple} {1 pineapple} {2 pineapple}} {{2 apple} {1 apple}}