在一個單元格中嵌套多個嵌套的Iif和計數語句

Question

我在Access2010 .mdb中有一個示例數據，如下所述，PipeId對於三個TVObservations是相同的。 FS，OB和RB描述了觀察的類型，我需要計算觀察次數。

的sampleData：

| PipeID | TVObservation | NumberOf | 
|--------|---------------|----------| 
| 301 |  FS  | 2  | 
| 301 |  OB  | 2  | 
| 301 |  RB  | 1  | 

所需輸出：

| PipeID |  NumberOf  | 
|--------|---------------------| 
| 301 | FS: 2, OB: 2, RB: 1 | 

我能得到的觀測次數，但有一個名稱返回的意見/前冠軍，在一個細胞被證明是困難的。

Count(Iif([TVObservation]="FS",True,IIf([TVObservation]="OB",True,IIf(TVObservation]="RB",True,Null)))) AS NumberOf 

Answer 1

作爲後續從什麼@ krish公里提到的，這裏是我改編自Allen Browne's ConcatRelated function（請注意，我去掉了很多原來的普通實用的功能，所以應該只使用爲您的具體情況）。

一個VBA模塊將這個......

Public Function ConcatRelated(strField1 As String, _ 
       strField2 As String, _ 
       strRelField As String, _ 
       lngRelFieldVal As Long, _ 
       strOrderBy As String, _ 
       strTable As String, _ 
       Optional strSeparator = ", ") As Variant 

On Error GoTo Err_Handler 

    Dim db As DAO.Database   ' Database 
    Dim rs As DAO.Recordset   ' 
    Dim strSql As String   ' SQL statement 
    Dim strOut As String   ' Output string to concatenate to. 
    Dim lngLen As Long    ' Length of string. 

    ' Initialize to Null 
    ConcatRelated = Null 

    ' Find related records limited by related field 
    strSql = "SELECT " & strRelField & ", " & strField1 & ", " & strField2 _ 
      & " FROM " & strTable & " WHERE " & strRelField & " = " & lngRelFieldVal _ 
      & " ORDER BY " & strOrderBy 

    Set db = CurrentDb 
    Set rs = db.OpenRecordset(strSql) 

    ' Loop through related fields to build comma separated list 
    Do While Not rs.EOF 
     strOut = strOut & rs.Fields(strField1) & ": " & rs.Fields(strField2) & strSeparator 
     rs.MoveNext   
    Loop 

    rs.Close 

    ' Return the string without the trailing separator. 
    lngLen = Len(strOut) - Len(strSeparator) 
    If _ 
     lngLen > 0 _ 
    Then 
     ConcatRelated = Left(strOut, lngLen) 
    End If 

Exit_Handler: 
    'Clean up 
    Set rs = Nothing 
    Set db = Nothing 
    Exit Function 

Err_Handler: 
    MsgBox "Error " & Err.Number & ": " & Err.Description, vbExclamation, "ConcatRelated()" 
    Resume Exit_Handler 

End Function 

然後您就可以在SQL語句中使用此功能。

第一個和第二個參數是您想要連接到逗號分隔列表的2個字段;這些作爲字符串傳遞，因此使用雙引號。

第三和第四個參數是這個字段的值在你試圖總結的記錄中是相同的（在你的情況下它是PipeID）。請注意，參數3需要使用雙引號"PipeID"，而參數4是sql引用字段，因此不得使用引號tblTvObservations.PipeID。

第五個參數是您在strField或strField2中指定的字段，您希望按逗號分隔列表排序。

第六個也是最後一個參數是該數據來自的表/查詢名稱。

下面是一個SQL查詢中使用它的一個例子...

SELECT tblTvObservations.PipeID, ConcatRelated("TVObservation","NumberOf","PipeID",tblTvObservations.PipeID,"TVObservation","tblTvObservations") AS NumberOf 
FROM tblTvObservations; 

...得到以下結果：