如何更改節點名和XML複製節點的數據到另一個使用XSLT

Question

我的基本XML就像

<?xml version="1.0" encoding="iso-8859-1"?> 
<Report version="1.0"> 
    <sourceName Identification="xyz"/> 
    <sourcesys Identification="mycomp"> 
    <Manager> 
     <ManagerNo>1023114455</ManagerNo> 
     <Address>Delhi,India</Address> 
     <Currency> 
     <CurrencyType>Rupee</CurrencyType> 
     </Currency> 
    </Manager> 
    <Manager> 
     <ManagerNo>236784455</ManagerNo> 
     <Address>California,USA</Address> 
     <Currency> 
     <CurrencyType>Dollar</CurrencyType> 
     </Currency> 
    </Manager> 
    </sourcesys> 
</Report> 

我想這個XML轉換爲以下一個

<?xml version="1.0" encoding="UTF-8" standalone="yes"?> 
<ManagerDetails xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
    <ManagerDetail> 
    <ManagerNo>1023114455</ManagerNo> 
    <Address> 
     <PermenantAdd>California,USA</PermenantAdd> 
    </Address> 
    <CurrencyID>Rupee</CurrencyID> 
    </ManagerDetail> 
    <ManagerDetail> 
    <ManagerNo>236784455</ManagerNo> 
    <Address> 
     <PermenantAdd>Delhi,India</PermenantAdd> 
    </Address> 
    <CurrencyID>Dollar</CurrencyID> 
    </ManagerDetail> 
</managerDetails> 

這裏是標籤的映射：

• sourcesys = managerDetails
• 經理=管理rDetail
• ManagerNo = ManagerNo
• 地址= PermenantAdd
• CurrencyType = CurrencyID

你怎麼會做這個使用XSLT？

Answer 1

對於這樣的轉變，你應該於identity template來構建其自身的副本的所有節點在XSLT

<xsl:template match="@*|node()"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

這意味着你只需要編寫您希望轉換的節點的模板（這就是說，全部由ManagerNo元素組成）。

要變換sourcesys（同樣爲經理），例如，你可以這樣做

<xsl:template match="sourcesys"> 
    <ManagerDetails> 
     <xsl:apply-templates select="@*|node()"/> 
    </ManagerDetails> 
</xsl:template> 

要刪除元素，如SOURCENAME你會只是忽略它的模板

<xsl:template match="sourceName"/> 

要處理地址這是不同略低因爲您需要添加新元素。在這種情況下，我會寫匹配的文本節點模板，並添加元素出現，比如：

<xsl:template match="Address/text()"> 
    <PermenantAdd> 
     <xsl:value-of select="." /> 
    </PermenantAdd> 
</xsl:template> 

最後，CurrencyType到CurrencyID，這是直接的，但你而且還需要一個模板來跳過父貨幣元素，並處理它的孩子，像這樣：

<xsl:template match="Currency "> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:template> 

試試這個XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/*"> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:template> 

    <xsl:template match="sourcesys"> 
     <ManagerDetails> 
     <xsl:apply-templates select="@*|node()"/> 
     </ManagerDetails> 
    </xsl:template> 

    <xsl:template match="Manager"> 
     <ManagerDetail> 
     <xsl:apply-templates select="@*|node()"/> 
     </ManagerDetail> 
    </xsl:template> 

    <xsl:template match="sourceName"/> 

    <xsl:template match="Address/text()"> 
     <PermenantAdd> 
     <xsl:value-of select="." /> 
     </PermenantAdd> 
    </xsl:template> 

    <xsl:template match="Currency"> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:template> 

    <xsl:template match="CurrencyType"> 
     <CurrencyID> 
     <xsl:apply-templates select="@*|node()"/> 
     </CurrencyID> 
    </xsl:template> 
</xsl:stylesheet> 

另請注意，有一個模板<xsl:template match="/*">跳過根元素，並且它是否具有命名空間也無所謂。

編輯：如果你不希望跨屬性複製爲sourcesys，而是使用新的屬性，嘗試更換像這樣

<xsl:template match="sourcesys"> 
     <ManagerDetails href="..."> 
     <xsl:apply-templates select="node()"/> 
     </ManagerDetails> 
    </xsl:template> 

通知模板如何XSL：申請模板現在缺少@*，所以它不會複製任何其他屬性。

如果你想

Answer 2

試試這個：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes" standalone="yes" encoding="utf-8" version="1.0"/> 

    <xsl:template match="/"> 
    <xsl:element name="ManagerDetails"> 
     <xsl:apply-templates /> 
    </xsl:element> 
    </xsl:template> 

    <xsl:template match="/Report/sourcesys/Manager"> 
    <xsl:element name="ManagerDetail"> 
     <xsl:apply-templates /> 
    </xsl:element> 
    </xsl:template> 

    <xsl:template match="/Report/sourcesys/Manager/ManagerNo"> 
    <xsl:copy-of select="."/> 
    </xsl:template> 

    <xsl:template match="/Report/sourcesys/Manager/Address"> 
    <xsl:copy> 
     <xsl:element name="PermenantAdd"> 
     <xsl:value-of select="."/> 
     </xsl:element> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/Report/sourcesys/Manager/Currency/CurrencyType"> 
    <xsl:element name="CurrencyID"> 
     <xsl:value-of select="."/> 
    </xsl:element> 
    </xsl:template> 

    <xsl:template match="text()"></xsl:template> 

</xsl:stylesheet>