使用批處理文件創建多個文件

Question

嗨誰能幫我解決這個問題。

我需要創建多個文件？我給任何例子。在某個文件夾中，比如文件夾記錄。 「記錄」文件夾按名稱「example2tought1023.au」包含1個文件。我需要生成相同的文件包含，多次只需增加數字。

我應該得到導致這樣example2tought1023.au example3tought1024.au example4tought1025.au example5tought1026.au

這是我目前有：

SET count=9 

SET filename_1=example 
SET filename_2=thought 

SET extension=.au 

SET start_1=2 
SET start_2=1023 

SET source=%filename_1%%start_1%%filename_2%%start_2%%extension% 

FOR /L %%i IN (1, 1, %count%) DO (
    REM These two lines do not work! 
    SET /a n=%start_1%+%%i 
    SET /a number_2=%start_2% + %%i 

    SET destination=%filename_1%%number_1%%filename_2%%number_2%%extension% 

    ECHO %destination% 
    REM COPY %source% %destination% 
) 

PAUSE 

但FOR /L循環線路不工作

Answer 1

你有誤識別哪些行不工作:-)

您有相對的問題當變量被擴展時變得更加艱難。使用百分比進行正常擴展時，會在解析該行時發生，並且您的整個FOR語句（包括括號括起來的DO子句）一次性解析。所以下面的一行

SET destination=%filename_1%%number_1%%filename_2%%number_2%%extension% 

是看到的價值觀％NUMBER_1％和％NUMBER_2％就存在被執行的循環之前。顯然不是你想要的。解決方案很簡單 - 您需要使用延遲擴展（運行時的值而不是解析時間）。您可以通過使用setlocal enableDelayedExpansion啓用延遲擴展功能，然後使用!number_1!而不是%number_1%來實現。

您與您的變量名稱（n vs number_1）不一致。

我想你想從0到count-1而不是從1到count。

在SET/A表達式中使用變量時，不必顯式擴展變量。您可以簡單地使用變量名稱而不用百分號或感嘆號。但是這隻適用於SET/A命令。

您還可以使用單個SET/A命令通過在每個賦值之間使用逗號來執行多個計算和賦值。

@echo off 
setlocal enableDelayedExpansion 

REM counts from 0 to count, so 8 = 9 copies 
set count=8 

set filename_1=example 
set filename_2=thought 

set extension=.au 

set start_1=2 
set start_2=1023 

set source=%filename_1%%start_1%%filename_2%%start_2%%extension% 

for /L %%i in (0, 1, %count%) do (
    set /a "number_1=start_1+%%i, number_2=start_2+%%i" 
    set destination=%filename_1%!number_1!%filename_2%!number_2!%extension% 
    echo !destination! 
    REM copy %source% !destination! 
) 

pause