通過批處理文件從文件讀取

Question

我有一個file.txt，其中包含安裝在我的機器上的oracles的路徑。 從註冊表 例如該文件包含：

ORACLE_HOME REG_SZ C:\oracle\product\11.2.0\dbhome_1 
    ORACLE_HOME REG_SZ C:\oracle\product\11.2.0\dbhome_2 

我通過我的批處理文件插入神諭到一個列表或類似列表中的所有路徑想要的。 如何在批處理文件中執行此操作？ 謝謝！

Answer 1

假設你想在內存中的值「列表」，而不是在一個文件中：

我想大多數人都喜歡的，可以通過索引值來訪問值的「陣列」。 （注 - 批處理沒有正式的數組，但可以模擬它們）。

只要沒有主路徑包含!，下面的簡單代碼就很有用。如果%%B包含!並且啓用延遲擴展，則擴展%%B將被損壞。

@echo off 
setlocal enableDelayedExpansion 

:: Read the file and create an "array" of home paths 
:: This will fail if any of the paths contain ! 
set /a cnt=0 
for /f "usebackq tokens=2*" %%A in ("file.txt") do (
    set /a cnt+=1 
    set "home.!cnt!=%%B" 
) 

:: Access the "array" members 
for /l %%N in (1 1 %cnt%) do echo !home.%%N! 

您可能可以在很多環境中運行上述代碼多年，並且永遠不會遇到問題。但是某個地方可能包含!在Oracle主路徑中。有許多策略可以解決上述問題以處理!。以下三個選項：

選項1 - 的代碼量最少，但最慢由於CALL

@echo off 
setlocal disableDelayedExpansion 

:: Read the file and create an "array" of home paths 
:: This will safely process all paths, regardless of value 
set /a cnt=0 
for /f "usebackq tokens=2*" %%A in ("file.txt") do (
    set /a cnt+=1 
    call set "home.%%cnt%%=%%B" 
) 

:: Access the "array" 
setlocal enableDelayedExpansion 
for /l %%N in (1 1 %cnt%) do echo !home.%%N! 

選項2 - 使用FINDSTR計數的行的一個有趣的和有效的方法。

@echo off 
setlocal disableDelayedExpansion 

:: Read the file and create an "array" of home paths 
:: This will safely process all paths, regardless of value 
set /a cnt=0 
for /f "tokens=1,3* delims=: " %%A in ('findstr /n "^" "file.txt"') do (
    set "home.%%A=%%C" 
    set "cnt=%%A" 
) 

:: Access the "array" members 
setlocal enableDelayedExpansion 
for /l %%N in (1 1 %cnt%) do echo !home.%%N! 

選項3 - 使用的是延遲擴展反覆的有效方法，但是最代碼

@echo off 
setlocal disableDelayedExpansion 

:: Read the file and create an "array" of home paths 
:: This will safely process all paths, regardless of value 
set /a cnt=0 
for /f "usebackq tokens=2*" %%A in ("file.txt") do (
    set /a cnt+=1 
    setlocal enableDelayedExpansion 
    for %%N in (!cnt!) do (
    endlocal 
    set "home.%%N=%%B" 
) 
) 

:: Access the "array" 
setlocal enableDelayedExpansion 
for /l %%N in (1 1 %cnt%) do echo !home.%%N! 

---

另外，也可以具有在單個變量的家用路徑列表。每條路徑都應該用引號括起來。路徑可以用空格，逗號，分號，平等或製表符分隔。我選擇了空間。

該列表的大小是有限的，因爲批處理環境變量的最大大小是〜8191字節。由於CALL，此解決方案也相對較慢。這些問題都不可能成爲現實世界中的問題。

@echo off 
setlocal disableDelayedExpansion 

:: Read the file and create a space delimited list of quoted home paths 
:: This will safely process all paths, regardless of value 
for /f "usebackq tokens=2*" %%A in ("file.txt") do (call set list=%%list%% "%%~B") 

:: optional - remove leading space 
(set list=%list:~1%) 

:: Display the list 
echo list=%list% 

:: Access the list members 
for %%F in (%list%) do echo %%~F 

Answer 2

for /f "tokens=3 delims= " %%a in (file.txt) do echo %%a >>paths.txt