在圖片框中旋轉圖片

Question

我目前正在編寫一款遊戲，該遊戲使用需要旋轉的箭頭來告訴用戶他們將「扔」他們的梨子的角度。我編寫了幾乎所有的解決方案，但是，我有箭頭作爲圖片框和其中的圖像。我需要能夠旋轉並記錄它旋轉的角度，我有一個計時器，我計劃每次旋轉圖像旋轉一個角度，並將角度變量添加一個角度。我唯一要做的就是旋轉圖像。你需要我可以給任何進一步的細節，

任何幫助是非常讚賞， 非常感謝， 丹

Private Function RotateImage(image As Image, angle As Single) As Bitmap 
    ' the calling code is responsible for (and must) 
    ' disposing of the bitmap returned 

    Dim retBMP As New Bitmap(image) 
    retBMP.SetResolution(image.HorizontalResolution, image.VerticalResolution) 

    Using g = Graphics.FromImage(retBMP) 
     ' rotate aroung the center of the image 
     g.TranslateTransform(image.Width \ 2, image.Height \ 2) 

     'rotate 
     g.RotateTransform(angle) 

     g.TranslateTransform(-image.Width \ 2, -image.Height \ 2) 

     'draw image to the new boitmap 
     g.DrawImage(retBMP, New PointF(0, 0)) 
    End Using 
    Return retBMP 
End Function 


Private Sub PowerTimer_Tick(sender As Object, e As EventArgs) Handles PowerTimer.Tick 

    If ArrowAngle >= 45 Then 
     AngleIncreasing = False 
    ElseIf ArrowAngle <= -45 Then 
     AngleIncreasing = True 
    End If 
    If AngleIncreasing = True Then 
     Arrow.Image = New Bitmap(Arrow.Image) 
     Arrow.Image = RotateImage(Arrow.Image, 1) 
     Me.Refresh() 
     ArrowAngle = ArrowAngle + 1 
    Else 
     Arrow.Image = RotateImage(Arrow.Image, 1) 
     Arrow.Image = RotateImage(Arrow.Image, -1) 
     Me.Refresh() 
     ArrowAngle = ArrowAngle - 1 
    End If 
End Sub 

Answer 1

沒有與the original code和VB翻譯的幾個問題。首先，CreateGraphics幾乎從不是正確的使用方式。之後，它被替換爲Graphics.FromImage中的一個。這是正確的方法，因爲您將繪製位圖，但都沒有放置，所以應用程序會泄漏。如果某個計時器正在旋轉，這可能是一個問題。

其次，C＃版本有缺陷：該方法需要傳遞一個偏移量，但可以計算（「如何使用」doest打擾傳遞偏移量）。最後，c＃版本也在泄漏。

Private Function RotateImage(img As Image, angle As Single) As Bitmap 
    ' the calling code is responsible for (and must) 
    ' disposing of the bitmap returned 

    Dim retBMP As New Bitmap(img.Width, img.Height) 
    retBMP.SetResolution(img.HorizontalResolution, img.VerticalResolution) 

    Using g = Graphics.FromImage(retBMP) 
     ' rotate aroung the center of the image 
     g.TranslateTransform(img.Width \ 2, img.Height \ 2) 

     'rotate 
     g.RotateTransform(angle) 

     g.TranslateTransform(-img.Width \ 2, -img.Height \ 2) 

     'draw image to the bitmap 
     g.DrawImage(img, New PointF(0, 0)) 

     Return retBMP 
    End Using 
End Function 

用法：

' form level var if rotating over and over 
Private CatImg As Bitmap 

' elsewhere: 
CatImg = New Bitmap("C:\Temp\ceiling_cat.jpg") 

' to create a new rotated image: 
Dim bmp = RotateImage(CatImg, -65) 
pb1.Image = bmp 

'ToDo: dispose of the picbox image 

結果（前後）：

角被截斷，因爲您的代碼不計算新的邊界矩形的大小。如果旋轉的東西在更大的圖像內，它仍然可以工作。

---

使用旋轉方法箭頭重定向回和定時器第四-90到90度：

Smoooth！很多將取決於要旋轉的圖像的性質，並且在這種情況下我們對圖像一無所知。瞥一眼TaskManager顯示沒有任何泄漏 - 一定要處理先前的圖像。