計數節點值

Question

說我有這樣的顏色列表：

<colors> 
    <color>Red</color> 
    <color>Green</color> 
    <color>Blue</color> 
</colors> 

和我有任何數量的項目的每一個都可以有一個顏色：

<items> 
    <item color="Blue"/> 
</items> 

現在我想要顯示每種顏色有多少項目有那種顏色：

<xsl:for-each select="//color"> 
    <xsl:value-of select="."/>: <xsl:value-of select="count(//item[@color = ...])"/>&#10; 
</xsl:for-each> 
No color: <xsl:value-of select="count(//item[not(@color)])"/> 

但我不知道如何選擇所有t他通過比較他們與當前的顏色。任何人都可以將我指向正確的方向嗎？

謝謝！

Answer 1

我建議你用key鏈接到它們的顏色的項目。例如，給定：

XML

<root> 
    <colors> 
     <color>Red</color> 
     <color>Green</color> 
     <color>Blue</color> 
    </colors> 
    <items> 
     <item color="Red"/> 
     <item color="Green"/> 
     <item color="Blue"/> 
     <item color="Green"/> 
     <item color="Blue"/> 
     <item color="Blue"/> 
    </items> 
</root> 

以下樣式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text" encoding="UTF-8"/> 

<xsl:key name="item-by-color" match="item" use="@color" /> 

<xsl:template match="/root"> 
    <xsl:for-each select="colors/color"> 
     <xsl:value-of select="."/> 
     <xsl:text>: </xsl:text> 
     <xsl:value-of select="count(key('item-by-color', .))"/> 
     <xsl:text>&#10;</xsl:text> 
    </xsl:for-each> 
</xsl:template> 

</xsl:stylesheet> 

將返回：

Red: 1 
Green: 2 
Blue: 3 

---

如果你也想算沒有顏色的項目，關鍵定義修改爲：

<xsl:key name="item-by-color" match="item" use="string(@color)" /> 

然後使用：

<xsl:value-of select="count(key('item-by-color', ''))"/>