Clojure中的雙端隊列

Question

Clojure中是否有雙端隊列？我的印象是Clojure的PersistentQueue是單端（我錯了嗎？）。我需要能夠從隊列的任何一端刪除數據（即「pop」）和「peek」。我對雙頭隊列的解釋是https://en.wikipedia.org/wiki/Double-ended_queue。

我看到Java有一個雙端隊列，但我不確定如何在Clojure中實例化隊列對象。 嘗試創建一個新的隊列：

(java.util.Dequeue.) 

給出錯誤：

No matching ctor found for interface java.util.Queue.

Answer 1

Is there a double-ended queue in Clojure?

AFAIK沒有。

My impression is Clojure's PersistentQueue is single ended (am I wrong?).

它只允許conj在結束和從開始peek/pop。

I see that Java has a double-ended queue, but I'm unsure how to instantiate the queue object in Clojure.

無法實例java.util.Queue，因爲它是一個interface。看一看子接口java.util.Deque與其實現類：

• ArrayDeque
• ConcurrentLinkedDeque
• LinkedBlockingDeque
• LinkedList

您可以創建和使用，例如，一個ArrayDeque如下：

(def deque (java.util.ArrayDeque. [1 2 3])) 
;;=> 'user/deque 

(.pollFirst deque) 
;;=> 1 

但是，您可能希望查看deque-clojure，它提供了Clojure中的持久實現，而不是在interop語法和可變集合中掙扎。

Answer 2

只是爲了completenes，純Clojure的版本可能是這樣的：

(defn deque 
    ([] 
    '[()()]) 
    ([& elems] 
    [elems '()])) 

(defn push-front [deque elem] 
    (let [[head tail] deque] 
    [(cons elem head) tail])) 

(defn push-back [deque elem] 
    (let [[head tail] deque] 
    [head (cons elem tail)])) 

(defn pop-front [deque] 
    (let [[head tail] deque] 
    (if (empty? head) 
     [(-> tail reverse rest) head] 
     [(rest head) tail]))) 

(defn pop-back [deque] 
    (let [[head tail] deque] 
    (if (empty? tail) 
     [tail (-> head reverse rest)] 
     [head (rest tail)]))) 

(defn peek-front [deque] 
    (let [[head tail] deque] 
    (if (empty? head) 
     (-> tail reverse first) 
     (first head)))) 

(defn peek-back [deque] 
    (let [[head tail] deque] 
    (if (empty? tail) 
     (-> head reverse first) 
     (first tail)))) 


;; usage example: 

user> (let [dq (deque)] 
     (-> dq 
      (push-front :a) 
      (push-front :b) 
      (peek-back))) 


:a 
user> (let [dq (deque)] 
     (-> dq 
      (push-front :a) 
      (push-front :b) 
      (pop-back))) 


[() (:b)] 

user> (let [dq (deque)] 
    (-> dq 
     (push-back :a) 
     (push-back :b) 
     (peek-back))) 
:b