我可以如何強迫我們的開發人員在通過TortoiseSVN提交時輸入筆記？

Question

我經常看到一些提交，但沒有引用票據的票據......所以我最終回去手動檢查差異。不一定是壞的，但有筆記會很高興。有任何想法嗎？

Answer 1

當然，但你將如何執行非亂碼，有意義和背景化的提交消息？

當你注意到一個跛腳/空洞的提交時，更好地衝你的不負責任的同事。或者口頭相當於一拳。只要確保他們感覺不好，這是應得的。

Answer 2

您可以定義一個預先提交掛鉤腳本，拒絕所有提交空白或太短的日誌消息。

這是關於如何做到的post。

Answer 3

我已經使用了預提交鉤子腳本來確保提交註釋始終引用問題跟蹤系統中的問題編號。例如，評論如

fixes frobulator when the moon is full (bug 1234)

將被接受，因爲它包含一個錯誤號。即使採用這種安排，您仍然必須相信開發人員才能插入有意義的評論和錯誤編號。

Answer 4

我們的預提交hookscript（Windows批處理）：

@echo off & setlocal ENABLEEXTENSIONS 

set SVNLOOK="E:\Subversion\Program\Subversion 1.5.0\bin\svnlook.exe" 

set REPOS=%1% 
set TXN=%2% 
set LOGFILE=%REPOS%\hooks\log-%TXN%.txt 
set GREP=E:\UnxUtils\usr\local\wbin\grep.exe 

%SVNLOOK% log -t "%TXN%" "%REPOS%" >%LOGFILE% 

set "first=" 
for /f "delims=" %%a in ('more ^< "%LOGFILE%"') do (
    if not defined first set first=%%a 
) 

del %LOGFILE% 

if not defined first (echo "Please supply a commit comment" >&2 & exit 1) 





REM Check for invalid windows characters in the path 
echo Checking >%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "\" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find ":" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "*" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "?" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find """" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^>" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^<" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^|" >>%LOGFILE% 

set "first=" 
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
    if not defined first set first=%%a 
) 

del %LOGFILE% 

if defined first (echo "Please do not use filename characters which are invalid in windows. - Found %first%" >&2 & exit 1) 






REM Tagblock - prevent changes to tag directories 
echo Checking >%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | %GREP% "^U.*\/tags\/.*" | %GREP% -v -f "%REPOS%\conf\tag-block-exceptions.txt" >>%LOGFILE% 

set "first=" 
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
    if not defined first set first=%%a 
) 

del %LOGFILE% 


if defined first ( 
    echo "%first% -- Error: Modifications to tag directories are blocked. To allow these modifications add the path to %REPOS%\conf\tag-block-exceptions.txt" >&2 
    exit 1) 

Answer 5

不TortoiseSVN的，但Subversion本身 - 在服務器上設置。您可以設置一個強制執行提交評論的預提交掛鉤。如果你想更進一步，還有一些預先提交的鉤子可以驗證是否存在對像Jira這樣的問題跟蹤系統的引用。

Answer 6

TortoiseSVN是客戶端，您可能需要force comments on the subversion server。 或者你可以告訴他們評論他們的提交。

Answer 7

您需要使用一個預先提交的鉤子，這是一個服務器設置，我已經爲VisualSVN編寫了一個基本上是批處理文件的鉤子 - 類似的腳本可用於基於非Windows的SVN服務器。

@echo off 
:: 
:: Stops commits that have empty log messages. 
:: 
@echo off 
setlocal 

rem Subversion sends through the path to the repository and transaction id 
set REPOS=%1 
set TXN=%2 

rem check for an empty log message 
call "C:\program files\visualsvn server\bin\svnlook" log %REPOS% -t %TXN% | findstr . > nul 
if %errorlevel% gtr 0 (goto err) else exit 0 

:err 
echo. 1>&2 
echo Your commit has been blocked because you didn't give any log message 1>&2 
echo Please write a log message describing the purpose of your changes and 1>&2 
echo then try committing again. -- Thank you 1>&2 
exit 1 

Answer 8

可以強制提交評論很輕鬆了，但你最終得到的是一百萬提交該說「調試」或「測試」。

如果您的開發人員看不到添加提交消息時強制他們鍵入的值不會改變這一點。

更糟糕的是，當Eclipse用戶將SVN/CVS集成到一起時，它會記住它們的最後一次提交消息 - 並且它們最終提交了一個完全不相關的文件，其中包含來自上一個任務/項目的消息。