如何刪除字符串的最後兩個「 - 」字符？

Question

我有一個字符串數組格式化爲這樣：

Ado-trastuzumab emtansine(HER2)02-22-2013 

我想刪除最後兩個「 - 」僅（從原來的字符串的日期部分）的符號，這樣的名字藥物（Ado-trastuzumab emtansine）未被改變。現在我正則表達式刪除所有「 - 」符號：

foreach my $string (@array) { 
    $string =~ tr/-//d; 
} 

我想輸出，而不是爲以下：

Ado-trastuzumab emtansine(HER2)02222013 

感謝您的幫助！

Answer 1

可以使用substr當作左值的音譯只適用於你的字符串的特定部分：

substr($string, -10, 10) =~ tr/-//d; 

在這種情況下，在字符串的最後10個字母。

Answer 2

foreach my $string (@array) { 
    $string =~ s/(\d{2})-(\d{2})-(\d{4})$/$1$2$3/; 
} 

Answer 3

要做到你說的話字面上 - 從字符串刪除最後兩個連字符 - 你可以寫這個

$string =~ s/-([^-]*)-([^-]*)\z/$1$2/; 

但在這種情況下，你可以簡單地刪除遵循一個數字的所有連字符：

$string =~ s/\d\K-//g; 

Answer 4

如果在只有一個-什麼應該做的事：

$s =~ s/-([^-]*)-([^-]*)\z/$1$2/; 

$s = reverse($s); 
$s =~ s/^([^-]*)-([^-]*)-/$1$2/; 
$s = reverse($s); 

$s = reverse(reverse($s) =~ s/^([^-]*)-([^-]*)-/$1$2/r); # 5.14+ 

所有這些工作，即使只有一個-：

$s =~ s/-([^-]*)(?:-([^-]*))?\z/$1$2/; 

$s =~ s/-([^-]*)\z/$1/ for 1..2; 

$s =~ s/^.*\K-//s for 1..2; 

$s = reverse($s); 
$s =~ s/-// for 1..2; 
$s = reverse($s); 

$s = reverse($s); 
$s =~ s/^([^-]*)-(?:([^-]*)-)?/$1$2/; 
$s = reverse($s); 

$s = reverse(reverse($s) =~ s/^([^-]*)-(?:([^-]*)-)?/$1$2/r); # 5.14+ 

對於長字符串，則reverse解決方案要快很多。對於短字符串，請閱讀。