故障轉換XML文檔URL

Question

編輯：實例現在包含有我的主文檔

大家在所有標籤！我只是對XSLT有個簡單的問題。我有一個很大的xml文件，其中嵌套了許多<DIMENSION_Id>節點。在每個<DIMENSION_Id>節點中有兩個SYN標記：<SYN>String</SYN><SYN>Integer</SYN>我想要做的是將每個DIMENSION_Id的最遠的子節點連接到它的所有祖先路徑以創建一個URL。

即

<DIMENSIONS VERSION="1.0.0"> 
    <DIMENSION NAME="Category" SRC_TYPE="INTERNAL"> 
     <DIMENSION_NODE ID="1000"/> 
     <DIMENSION_Id> 
      <SYN>Text</SYN> 
      <SYN>Number</SYN> 
      <DIMENSION_Id> 
       <SYN>More Text</SYN> 
       <SYN>Another Number</SYN> 
      </DIMENSION_Id> 
     </DIMENSION_Id> 
    </DIMENSION> 
</DIMENSIONS> 

我寫了這個XSLT先獲得從父節點的所有信息，然後最後創建一個完整的URL子節點。不幸的是，它只給了我最遠的子節點的信息......我不知道如何附加任何其他文本。 （應改爲類似：最遠的父/接近父/母/ item_selected）

不幸的是它是所有給我當前節點的值....下面是我寫的XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" /> 
    <xsl:template match="/DIMENSION_NODE"> 
     <xsl:for-each select="ancestor-or-self::*"> 
      <xsl:value-of select="@SYN" /> 
      <xsl:text>/</xsl:text> 
      <xsl:value-of select="." /> 
      <xsl:value-of select="@SYN" /> 
      <xsl:text>/</xsl:text> 
      <xsl:value-of select="." /> 
     </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

在此先感謝您的幫助！

Answer 1

編輯：輸入樣本更接近問題。

有了這個輸入：

<DIMENSIONS VERSION="1.0.0"> 
    <DIMENSION NAME="Category" SRC_TYPE="INTERNAL"> 
     <DIMENSION_NODE ID="1000"/> 
     <DIMENSION_Id> 
      <SYN>Text</SYN> 
      <SYN>1</SYN> 
      <DIMENSION_Id> 
       <SYN>More Text</SYN> 
       <SYN>2</SYN> 
      </DIMENSION_Id> 
     </DIMENSION_Id> 
    </DIMENSION> 
</DIMENSIONS> 

兩個選項。

1）應用模板和模式，以祖先：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:template match="text()"/> 
    <xsl:template match="SYN[number()!=.]"> 
     <xsl:apply-templates select="ancestor::DIMENSION_Id" mode="output"/> 
     <xsl:value-of select="concat(' ',../SYN[number()=.],'&#xA;')"/> 
    </xsl:template> 
    <xsl:template match="DIMENSION_Id" mode="output"> 
     <xsl:value-of select="concat('/',SYN[number()!=.])"/> 
    </xsl:template> 
</xsl:stylesheet> 

2）使用參數：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:template match="text()"/> 
    <xsl:template match="SYN[number()!=.]"> 
     <xsl:param name="pPath"/> 
     <xsl:value-of select="concat($pPath,' ',../SYN[number()=.],'&#xA;')"/> 
    </xsl:template> 
    <xsl:template match="DIMENSION_Id"> 
     <xsl:param name="pPath"/> 
     <xsl:apply-templates> 
      <xsl:with-param name="pPath" 
           select="concat($pPath,'/',SYN[number()!=.])"/> 
     </xsl:apply-templates> 
    </xsl:template> 
</xsl:stylesheet> 

兩個輸出：

/Text 1 
/Text/More Text 2 

Answer 2

我猜你想要這個 ：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 

<xsl:template match="DIMENSION_Id[not(DIMENSION_Id)]"> 
    <xsl:apply-templates select="(.|ancestor::DIMENSION_Id)/SYN" mode="gen"/> 
</xsl:template> 

<xsl:template match="SYN" mode="gen"> 
    <xsl:value-of select="concat('/',.)"/> 
</xsl:template> 
<xsl:template match="text()"/> 
</xsl:stylesheet> 

當這個變換所提供的XML文檔應用（校正爲良好的形成）：

<DIMENSIONS VERSION="1.0.0"> 
    <DIMENSION NAME="Category" SRC_TYPE="INTERNAL"> 
     <DIMENSION_NODE ID="1000"/> 
     <DIMENSION_Id> 
      <SYN>Text</SYN> 
      <SYN>Number</SYN> 
      <DIMENSION_Id> 
       <SYN>More Text</SYN> 
       <SYN>Another Number</SYN> 
      </DIMENSION_Id> 
     </DIMENSION_Id> 
</DIMENSION> 
</DIMENSIONS> 

有用，正確的結果產生：

/Text/Number/More Text/Another Number 

Answer 3

對不起，每個人都感到困惑。我得到了一些幫助，這裏是解決方案：

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 

    <xsl:template match="/"> 
     <URLs> 
      <xsl:apply-templates select="//DIMENSION_NODE"/> 
     </URLs> 
    </xsl:template> 

    <xsl:template match="DIMENSION_NODE"> 
     <xsl:call-template name="getPath"> 
      <xsl:with-param name="currentnode" select="."/> 
     </xsl:call-template> 
    </xsl:template> 

    <xsl:template name="getPath"> 
     <xsl:param name="currentnode"/> 
     <xsl:param name="currenttext" select="''"/> 
     <xsl:param name="firstrun" select="1"/> 
     <xsl:choose> 
      <xsl:when test="$currentnode[parent::DIMENSION]"> 
       <URL> 
        <xsl:value-of select="$currenttext"/> 
       </URL> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:choose> 
        <xsl:when test="$firstrun = 1"> 
         <xsl:variable name="gettext"> 
          <xsl:text>/</xsl:text> 
          <xsl:value-of select="concat($currentnode/DVAL/SYN[1],'&#x9;',$currentnode/DVAL/DVAL_ID/@ID)"/> 
         </xsl:variable> 
         <xsl:call-template name="getPath"> 
          <xsl:with-param name="currentnode" select="$currentnode/.."/> 
          <xsl:with-param name="currenttext" select="concat($gettext,$currenttext)"/> 
          <xsl:with-param name="firstrun" select="0"/> 
         </xsl:call-template> 
        </xsl:when> 
        <xsl:otherwise> 
         <xsl:variable name="gettext"> 
          <xsl:text>/</xsl:text> 
          <xsl:value-of select="$currentnode/DVAL/SYN[1]"/> 
         </xsl:variable> 
         <xsl:call-template name="getPath"> 
          <xsl:with-param name="currentnode" select="$currentnode/.."/> 
          <xsl:with-param name="currenttext" select="concat($gettext,$currenttext)"/> 
          <xsl:with-param name="firstrun" select="0"/> 
         </xsl:call-template> 
        </xsl:otherwise> 
       </xsl:choose> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

此外，我在我的XML文件中的錯誤道歉。