Salesforce - 根據工作日是關閉還是處於特定狀態計算工作日年齡

Question

我試圖創建一個公式，可以告訴我工作日中的案例的年齡，如果它打開，關閉或處於具體狀況。這是我到目前爲止有：

IF(OR(IsNull(ClosedDate), IsNull(Waiting_Confirmation_Date__c)), 

(
    5*FLOOR((TODAY()-DATE(1996,01,01))/7) + 
    MIN(5, MOD(TODAY()-DATE(1996,01,01), 7)) 
) - (
    5*FLOOR((DATEVALUE(CreatedDate)-DATE(1996,01,01))/7) + 
    MIN(5, MOD(DATEVALUE(CreatedDate)-DATE(1996,01,01), 7)) 
), 

IF(NOT(IsNull(Waiting_Confirmation_Date__c)), 
(
    5*FLOOR((Waiting_Confirmation_Date__c - DATE(1996,01,01))/7) + 
    MIN(5, MOD(Waiting_Confirmation_Date__c - DATE(1996,01,01), 7)) 
) - (
    5*FLOOR((DATEVALUE(CreatedDate)-DATE(1996,01,01))/7) + 
    MIN(5, MOD(DATEVALUE(CreatedDate)-DATE(1996,01,01), 7)) 
), 

(
    5*FLOOR((DATEVALUE(ClosedDate)-DATE(1996,01,01))/7) + 
    MIN(5, MOD(DATEVALUE(ClosedDate)-DATE(1996,01,01), 7)) 
) - (
    5*FLOOR((DATEVALUE(CreatedDate)-DATE(1996,01,01))/7) + 
    MIN(5, MOD(DATEVALUE(CreatedDate)-DATE(1996,01,01), 7)) 
)) 


) 

我設置Waiting_Confirmation_Date__c與指定當用戶設置的情況下，以特定的狀態今天的日期的工作流。基本上我想要做的是這樣的：

如果案件未關閉或未在等待確認中（其中將設置「Waiting_Confirmation_Date__c」）將業務年齡設置爲創建時的年齡今天。

否則，如果設置了「Waiting_Confirmation_Date__c」，則將創建時間與確認日期之間的年齡時間設置爲。

最後，如果它已關閉，請將其設置爲從創建到關閉時的時間。

我認爲只是我的if/else不知何故是錯誤的，但我正在全心全意地弄清楚。

謝謝！

Answer 1

這似乎是一個相當痛苦的公式。你可以嘗試安裝免費的Case Age In Business Hours app from the AppExchange;它可能會做你需要的東西，如果沒有，它仍然是開源的，所以你可以修改它以滿足你的需求。

Answer 2

的解決方案是這樣，謝謝你們：

IF(AND(IsClosed), 

(
5*FLOOR((DATEVALUE(ClosedDate)-DATE(1996,01,01))/7) + 
MIN(5, MOD(DATEVALUE(ClosedDate)-DATE(1996,01,01), 7)) 
) - (
5*FLOOR((DATEVALUE(CreatedDate)-DATE(1996,01,01))/7) + 
MIN(5, MOD(DATEVALUE(CreatedDate)-DATE(1996,01,01), 7)) 
), 

IF(NOT(IsNull(Waiting_Confirmation_Date__c)), 
(
5*FLOOR((Waiting_Confirmation_Date__c - DATE(1996,01,01))/7) + 
MIN(5, MOD(Waiting_Confirmation_Date__c - DATE(1996,01,01), 7)) 
) - (
5*FLOOR((DATEVALUE(CreatedDate)-DATE(1996,01,01))/7) + 
MIN(5, MOD(DATEVALUE(CreatedDate)-DATE(1996,01,01), 7)) 
), 

(
5*FLOOR((TODAY()-DATE(1996,01,01))/7) + 
MIN(5, MOD(TODAY()-DATE(1996,01,01), 7)) 
) - (
5*FLOOR((DATEVALUE(CreatedDate)-DATE(1996,01,01))/7) + 
MIN(5, MOD(DATEVALUE(CreatedDate)-DATE(1996,01,01), 7)) 
)))