gnuplot - 如何使zmin等於Z軸上的zmax保持自動縮放

Question

如何使z軸上的縮放比例在zy軸上對稱：zmax = zmin，保持z軸上的自動縮放打開？ （GNUPLOT 5.0）

resulting graph - 3d-polar.png

是否有這種可能性在GNUPLOT或僅cbrange的固定的範圍，可以使用？

一個用於極積熱圖的例子：

reset 
set terminal pngcairo size 800,800 
set output '3d-polar.png' 
set lmargin at screen 0.05 
set rmargin at screen 0.85 
set bmargin at screen 0.1 
set tmargin at screen 0.9 

set pm3d map 
unset key 
set multiplot 

set parametric 
set grid xtics ytics 

set angles degree 
set autoscale xfix 
set autoscale yfix 
set autoscale zfix 
set palette model RGB defined (0"black", 1"white", 2"grey") 
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3 
unset multiplot 

的_FullWV.dat文件是here。

Answer 1

您可以使用stats來提取第3列的最小值和最大值，並相應地定義cbrange。

reset 
set terminal pngcairo size 800,800 
set output '3d-polar.png' 
set lmargin at screen 0.05 
set rmargin at screen 0.85 
set bmargin at screen 0.1 
set tmargin at screen 0.9 

set pm3d map 
unset key 
set multiplot 

stats '_FullWV.dat' using 3 
max(a,b) = (a>b) ? a : b 

Z_MAX = max(-STATS_min, STATS_max) 

set parametric 
set grid xtics ytics 

set angles degree 
set autoscale xfix 
set autoscale yfix 
#set zrange [-Z_MAX : Z_MAX] 
set cbrange [-Z_MAX : Z_MAX] 

set palette model RGB defined (0"black", 1"white", 2"grey") 
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3 
unset multiplot