如何找到字符串中的字位置（不是字符位置）

Question

假設我有一個由空格/連字符分隔的字符串。

例如，把這些折斷的翅膀，學習飛翔。

什麼vba函數可以找到應該返回爲3的單詞斷開的位置，而不是11這是字符位置。

Answer 1

一個解決方案（有可能是一種更有效的方式）將返回數組到分割字符串和迭代：

Function wordPosition(sentence As String, searchWord As String) As Long 

    Dim words As Variant 
    Dim i As Long 

    words = Split(sentence, " ") 
    For i = LBound(words, 1) To UBound(words, 1) 
     If words(i) = searchWord Then Exit For 
    Next i 

    'return -1 if not found 
    wordPosition = IIf(i > UBound(words, 1), -1, i + 1) 

End Function 

你可以稱它爲ILKE這樣的：

Sub AnExample() 

    Dim s As String 
    Dim sought As String 

    s = "Take these broken wings and learn to fly" 
    sought = "broken" 

    MsgBox sought & " is in position " & wordPosition(s, sought) 

End Sub 

Answer 2

的由assylias提出的解決方案是相當不錯的，只需要一個小適應，以解決多個事件：

Function wordPosition(sentence As String, searchWord As String) As Long() 

    Dim words As Variant 
    Dim i As Long 

    words = Split(sentence, " ") 
    Dim matchesCount As Long: matchesCount = 0 
    ReDim matchesArray(UBound(words) + 1) As Long 
    For i = LBound(words, 1) To UBound(words, 1) 
     If words(i) = searchWord Then 
      matchesCount = matchesCount + 1 
      matchesArray(matchesCount) = IIf(i > UBound(words, 1), -1, i + 1) 
     End If 
    Next i 

    If (matchesCount > 0) Then 
     matchesArray(0) = matchesCount 
    End If 

    wordPosition = matchesArray 

End Function 


Sub AnExample() 

    Dim s As String 
    Dim sought As String 

    s = "Take these broken wings and learn to fly and broken again" 
    sought = "broken" 

    Dim matches() As Long: matches = wordPosition(s, sought) 

    If (matches(0) > 0) Then 
     Dim count As Integer: count = 0 
     Do 
      count = count + 1 
      MsgBox "Match No. " & count & " for " & sought & " is in position " & matches(count) 
     Loop While (count < matches(0)) 

    End If 

End Sub