創建XSLT爲組數據

Question

我有這樣的XML數據：

<data ItemCount="5"> 
<zrow GroupName="Manager"User="User1" /> 
<zrow GroupName="Developer"User="User2" /> 
<zrow GroupName="Manager"User="User3" /> 
<zrow GroupName="CEO"User="User4" /> 
<zrow GroupName="CEO"User="User5" /> 
</data> 

我想這樣的輸出：

Manager 

User1 

User3 

Developer 

User2 

CEO 

User4 

User5 

什麼應該是我的XSLT？我想創建一個XSLT，它應該將我的數據轉換爲上述格式。你能幫我創建一個嗎？

Answer 1

的XSLT 2.0溶液：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:template match="data"> 
     <xsl:for-each-group select="zrow" group-by="@GroupName"> 
      <xsl:value-of select="current-grouping-key()" /> 
      <xsl:text>&#xa;</xsl:text> 
      <xsl:value-of select="current-group()/@User" separator="&#xa;"/> 
      <xsl:text>&#xa;</xsl:text> 
     </xsl:for-each-group> 
    </xsl:template> 
</xsl:stylesheet> 

的XSLT 1.0解決方案依賴於Muenchian方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:strip-space elements="*"/> 
    <xsl:key name="byGroupName" match="zrow" use="@GroupName"/> 
    <xsl:template 
     match="zrow[generate-id()= 
        generate-id(key('byGroupName', @GroupName)[1])]"> 
     <xsl:value-of select="@GroupName"/> 
     <xsl:text>&#xa;</xsl:text> 
     <xsl:apply-templates select="key('byGroupName', @GroupName)" mode="out"/> 
    </xsl:template> 
    <xsl:template match="zrow" mode="out"> 
     <xsl:value-of select="@User"/> 
     <xsl:text>&#xa;</xsl:text> 
    </xsl:template> 
    <xsl:template match="zrow"/> 
</xsl:stylesheet>