如何獲得一組獨特的值？

Question

給定某種值的集合（一個數組或某種集合），我如何生成一組不同的值？

Answer 1

使用Scripting.Dictionary（工具 - >引用... - >Microsoft腳本運行時）：

Function Unique(values As Variant) As Variant() 
    'Put all the values as keys into a dictionary 
    Dim dict As New Dictionary 
    Dim val As Variant 
    For Each val In values 
     dict(val) = 1 
    Next 
    Unique = dict.Keys 'This cannot be done with a Collection, which doesn't expose its keys 
End Function 

在VBScript或VBA，如果你喜歡使用後期綁定（變量，但不顯式類型）：

Function Unique(values) 
    Dim dict, val 
    Set dict = CreateObject("Scripting.Dictionary") 
    For Each val In values 
    ... 

如果在Mac（沒有Microsoft腳本運行時）上運行VBA，有一個drop-in replacement for Dictionary可用。

一些例子：

• Extracting the collection of unique values from a filter in VBA
• Delete duplicate entries in a given row
• How to remove duplicate items in listbox
• How to get unique values from a list of values using VBscript?
• VBScript:Remove duplicates from an array
• Word occurrences in VBA
• Find all distinct values in user based selection - Excel VBA

---

另一種選擇（僅VBA）是使用Collection。這是一個稍微尷尬，因爲沒有辦法設置沒有錯誤的現有密鑰被拋出，因爲返回的數組必須手動創建：

Function Unique(values As Variant) As Variant() 
    Dim col As New Collection, val As Variant, i As Integer 
    For Each val In values 
     TryAdd col, val, val 
    Next 
    Dim ret() As Variant 
    Redim ret(col.Count - 1) 
    For i = 0 To col.Count-1 
     ret(i) = col(i+1) 
    Next 
    Unique = ret 
End Function 

Sub TryAdd(col As Collection, item As Variant, key As String) 
    On Error Resume Next 
    col.Add(item, key) 
End Sub