找到一個單一標籤內的同一內標籤內容的n個

Question

如何讓

<BOOK-REF ID="Kyle-ch001-bib036"><AUTHOR-REF><SURNAME>Neinstein</SURNAME>, <GIVEN-NAME>L. S.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Gordon</SURNAME>, <GIVEN-NAME>C. G.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Katzman</SURNAME>, <GIVEN-NAME>D.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Rosen</SURNAME>, <GIVEN-NAME>D.</GIVEN-NAME></AUTHOR-REF>, &#x0026; <AUTHOR-REF><SURNAME>Woods</SURNAME>, <GIVEN-NAME>E.</GIVEN-NAME></AUTHOR-REF> (<YEAR-REF>2007</YEAR-REF>). <BOOK-TITLE-REF>Adolescent health care: A practical guide</BOOK-TITLE-REF> (<EDITION-REF>5th ed.</EDITION-REF>). <PLACE-OF-PUBLICATION-REF>Philadelphia</PLACE-OF-PUBLICATION-REF>: <PUBLISHER-REF>Lippincott Williams and Wilkins</PUBLISHER-REF>.</BOOK-REF> 

我只是想獲得其內容的單一標籤內呈現不換行字符相同標記的內部標籤內容值（單獨名）內thenametag和書REF標記內呈現，姓標籤可以呈現n倍，我想在數組中的內容預先

my (@arr2); 
while ($str =~ /<BOOK-REF ID="([^"]*)">(?:[^\)]*)<SURNAME>(.*?)<\/SURNAME>.*?<YEAR-REF>(\d+\w+)<\/YEAR-REF>.*?<\/BOOK-REF>/sgi){ 
    my $id = $1; 
    my $sname = $2; 
    my $year = $3; 
    push (@arr2,[$id,$sname,$year]); 
} 

感謝

Answer 1

使用XML::XSH2：

#!/usr/bin/perl 

use warnings; 
use strict; 

use Data::Dumper; 

use XML::XSH2; 
xsh << ' end xsh;'; 
    open 1.xml ; 
    for //SURNAME { 
     $y = string(../../YEAR-REF) ; 
     $s = string(.) ; 
     $i = string(ancestor::BOOK-REF/@ID) ; 
     perl { push @arr, [$i, $s, $y] } } 
    end xsh; 
print Dumper \@XML::XSH2::Map::arr; 

Answer 2

With XML :: Twig。我在書中添加了一個包裝books，以防文件中有多個文件。沒有它，代碼的工作原理是一樣的。

#!/usr/bin/perl 

use strict; 
use warnings; 

use YAML; 
use XML::Twig; 

my @by_name; 
XML::Twig->new(twig_handlers => { 'BOOK-REF' => sub { book_ref(@_, \@by_name); } }) 
     -> parse(\*DATA); 

print Dump \@by_name; 

sub book_ref 
    { my($t, $bookref, $by_name)= @_; 
    foreach my $surname ($bookref->descendants('SURNAME')) 
     { push @$by_name, { name => $surname->text, id => $bookref->att('ID'), year => $bookref->field('YEAR-REF') }; } 
    $t->purge; # if the file can be too big to fit in memory 
    } 



__DATA__ 
<books> 
<BOOK-REF ID="Kyle-ch001-bib036"><AUTHOR-REF><SURNAME>Neinstein</SURNAME>, <GIVEN-NAME>L. S.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Gordon</SURNAME>, <GIVEN-NAME>C. G.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Katzman</SURNAME>, <GIVEN-NAME>D.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Rosen</SURNAME>, <GIVEN-NAME>D.</GIVEN-NAME></AUTHOR-REF>, &#x0026; <AUTHOR-REF><SURNAME>Woods</SURNAME>, <GIVEN-NAME>E.</GIVEN-NAME></AUTHOR-REF> (<YEAR-REF>2007</YEAR-REF>). <BOOK-TITLE-REF>Adolescent health care: A practical guide</BOOK-TITLE-REF> (<EDITION-REF>5th ed.</EDITION-REF>). <PLACE-OF-PUBLICATION-REF>Philadelphia</PLACE-OF-PUBLICATION-REF>: <PUBLISHER-REF>Lippincott Williams and Wilkins</PUBLISHER-REF>.</BOOK-REF> 
</books> 

Answer 3

使用XPath查詢來提取您感興趣的價值觀這三個XPath查詢應該返回你正在尋找的值：

//BOOK-REF/@ID 
//BOOK-REF/AUTHOR-REF/SURNAME 
//BOOK-REF/YEAR-REF 

要做到XPath查詢，使用類似XML::LibXML。完整的例子：

#!/usr/bin/perl 
use strict; 
use warnings; 
use XML::LibXML; 

my $xml = XML::LibXML->load_xml(string => q{<?xml version="1.0" encoding="utf-8"?> 
<BOOK-REF ID="Kyle-ch001-bib036"><AUTHOR-REF><SURNAME>Neinstein</SURNAME>, <GIVEN-NAME>L. S.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Gordon</SURNAME>, <GIVEN-NAME>C. G.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Katzman</SURNAME>, <GIVEN-NAME>D.</GIVEN-NAME></AUTHOR-REF>, <AUTHOR-REF><SURNAME>Rosen</SURNAME>, <GIVEN-NAME>D.</GIVEN-NAME></AUTHOR-REF>, &#x0026; <AUTHOR-REF><SURNAME>Woods</SURNAME>, <GIVEN-NAME>E.</GIVEN-NAME></AUTHOR-REF> (<YEAR-REF>2007</YEAR-REF>). <BOOK-TITLE-REF>Adolescent health care: A practical guide</BOOK-TITLE-REF> (<EDITION-REF>5th ed.</EDITION-REF>). <PLACE-OF-PUBLICATION-REF>Philadelphia</PLACE-OF-PUBLICATION-REF>: <PUBLISHER-REF>Lippincott Williams and Wilkins</PUBLISHER-REF>.</BOOK-REF> 
}); 

my $xc = XML::LibXML::XPathContext->new($xml); 

my $id = $xc->find('//BOOK-REF/@ID'); 
my @snames = map $_->textContent => $xc->findnodes('//BOOK-REF/AUTHOR-REF/SURNAME'); 
my $year = $xc->find('//BOOK-REF/YEAR-REF'); 

print "$id\n"; 
print join(', ' => @snames), "\n"; 
print "$year\n"; 

# prints: 
# Kyle-ch001-bib036 
# Neinstein, Gordon, Katzman, Rosen, Woods 
# 2007 

你可以保存很好的結果是這樣一個數組：

push @some_array, +{ 
    id  => $id, 
    snames => \@snames, 
    year => $year 
}; 

如果你想按照你的原方案，複製ID和一年的每SNAME，那麼它的：

push @arr2, map [ $id, $_, $year ] => @snames; 

來存儲它們會在鍵入在id字段的哈希另一個潛在有用的方式，所以

$some_hash{$id} = +{ 
    id  => $id, 
    snames => \@snames, 
    year => $year 
};