如何從Perl的DBI獲取模式？

Question

我正在使用Perl DBI。我知道$dbase->tables()將返回相應數據庫中的所有表。同樣，我想知道數據庫中可用的模式。有沒有可用的功能？

Answer 1

什麼你要找的是：DBI->table_info()

這樣稱呼它：

my $sth = $dbh->table_info('', '%', ''); 
my $schemas = $dbh->selectcol_arrayref($sth, {Columns => [2]}); 
print "Schemas: ", join ', ', @$schemas; 

Answer 2

這是有效的。

創建數據庫：

echo 'create table foo (bar integer primary key, quux varchar(30));' | sqlite3 foobar.sqlite 

Perl程序打印模式：

use 5.010; 
use Data::Dumper qw(Dumper); 
use DBIx::Class::Schema::Loader qw(); 
DBIx::Class::Schema::Loader->naming('current'); 
DBIx::Class::Schema::Loader->use_namespaces(1); 

my $dbi_dsn = 'dbi:SQLite:dbname=foobar.sqlite'; 
my ($dbi_user, $dbi_pass); 
my $schema = DBIx::Class::Schema::Loader->connect(
    $dbi_dsn, $dbi_user, $dbi_pass, {'AutoCommit' => 1, 'RaiseError' => 1,} 
); 

for my $source_name ($schema->sources) { 
    say "*** Source: $source_name"; 
    my $result_source = $schema->source($source_name); 
    for my $column_name ($result_source->columns) { 
     say "Column: $column_name"; 
     say Dumper $result_source->column_info($column_name); 
    } 
} 

輸出：

*** Source: Foo 
Column: bar 
$VAR1 = { 
      'data_type' => 'integer', 
      'is_auto_increment' => 1, 
      'is_nullable' => 1 
     }; 

Column: quux 
$VAR1 = { 
      'data_type' => 'varchar', 
      'is_nullable' => 1, 
      'size' => 30 
     }; 

Answer 3

使用ODBC Oracle數據庫，我不得不使用上阿尼叔叔的回答這種變化：嘗試使用selectcol_arrayref($sth, ...)當

my $table_info = $dbh->table_info(undef, '%', undef); 
my $schemas = $table_info->fetchall_arrayref([1]); 

print "Schemas :\n", 
     join("\n", map {$_->[0]} @$schemas), "\n"; 

否則，$schemas將是不確定的。