vba將字符串轉換爲int如果字符串是數字

Question

我需要將從VBA中獲取的字符串從excel中轉​​換爲整數。爲此，我使用了CInt（），它運行良好。但是有機會的話，該字符串可能比許多其他的東西，在這種情況下，我需要設置整數爲0。目前我有：

If oXLSheet2.Cells(4, 6).Value <> "example string" Then 
    currentLoad = CInt(oXLSheet2.Cells(4, 6).Value) 
Else 
    currentLoad = 0 
End If 

的問題是，我無法預測所有可能的非數字可能在這個單元格中的字符串。有沒有一種方法可以告訴它轉換，如果它是一個整數，並設置爲0，如果不是？

乾杯 帽

Answer 1

使用則IsNumeric。如果它是一個數字，則返回true，否則返回false。

Public Sub NumTest() 
    On Error GoTo MyErrorHandler 

    Dim myVar As Variant 
    myVar = 11.2 'Or whatever 

    Dim finalNumber As Integer 
    If IsNumeric(myVar) Then 
     finalNumber = CInt(myVar) 
    Else 
     finalNumber = 0 
    End If 

    Exit Sub 

MyErrorHandler: 
    MsgBox "NumTest" & vbCrLf & vbCrLf & "Err = " & Err.Number & _ 
     vbCrLf & "Description: " & Err.Description 
End Sub 

Answer 2

把它放在一個行：

currentLoad = IIf(IsNumeric(oXLSheet2.Cells(4, 6).Value), CInt(oXLSheet2.Cells(4, 6).Value), 0) 

Answer 3

試試這個： currentLoad = ConvertToLongInteger(oXLSheet2.Cells(4, 6).Value) 使用此項功能：

Function ConvertToLongInteger(ByVal stValue As String) As Long 
On Error GoTo ConversionFailureHandler 
ConvertToLongInteger = CLng(stValue) 'TRY to convert to an Integer value 
Exit Function   'If we reach this point, then we succeeded so exit 

ConversionFailureHandler: 
'IF we've reached this point, then we did not succeed in conversion 
'If the error is type-mismatch, clear the error and return numeric 0 from the function 
'Otherwise, disable the error handler, and re-run the code to allow the system to 
'display the error 
If Err.Number = 13 Then 'error # 13 is Type mismatch 
     Err.Clear 
     ConvertToLongInteger = 0 
     Exit Function 
Else 
     On Error GoTo 0 
     Resume 
End If 
End Function 

我選擇龍（整數），而不是簡單的整型的，因爲整數在VBA中的最小/最大大小很差（最小值：-32768，最大值：+32767）。在電子表格操作中，通常在該範圍外有一個整數。

上面的代碼可以修改爲處理從字符串到整數，到貨幣（使用CCur（）），到十進制（使用CDec（）），到雙（使用CDbl（））等的轉換。只需要替換轉換函數本身（CLng）。更改函數返回類型，並重命名函數變量的所有匹配項以使所有內容保持一致。

Answer 4

這裏有三個可能有用的功能。首先檢查字符串是否爲正確的數字格式，第二個和第三個函數將字符串轉換爲Long或Double。

Function IsValidNumericEntry(MyString As String) As Boolean 
'******************************************************************************** 
'This function checks the string entry to make sure that valid digits are in the string. 
'It checks to make sure the + and - are the first character if entered and no duplicates. 
'Valid charcters are 0 - 9, + - and the . 
'******************************************************************************** 
Dim ValidEntry As Boolean 
Dim CharCode As Integer 
Dim ValidDigit As Boolean 
Dim ValidPlus As Boolean 
Dim ValidMinus As Boolean 
Dim ValidDecimal As Boolean 
Dim ErrMsg As String 

ValidDigit = False 
ValidPlus = False 
ValidMinus = False 
ValidDecimal = False 

ValidEntry = True 
For x = 1 To Len(MyString) 
    CharCode = Asc(Mid(MyString, x, 1)) 
    Select Case CharCode 

    Case 48 To 57 ' Digits 0 - 9 
     ValidDigit = True 

    Case 43 ' Plus sign 

    If ValidPlus Then 'One has already been detected and this is a duplicate 
     ErrMsg = "Invalid entry....too many plus signs!" 
     ValidEntry = False 
     Exit For 
    ElseIf x = 1 Then 'if in the first positon it is valide 
     ValidPlus = True 
    Else 'Not in first position and it is invalid 
     ErrMsg = "Invalide entry....Plus sign not in the correct position! " 
     ValidEntry = False 
     Exit For 
    End If 

    Case 45 ' Minus sign 

    If ValidMinus Then 'One has already been detected and this is a duplicate 
     ErrMsg = "Invalide entry....too many minus signs! " 
     ValidEntry = False 
     Exit For 
    ElseIf x = 1 Then 'if in the first position it is valid 
     ValidMinus = True 
    Else 'Not in first position and it is invalid 
     ErrMsg = "Invalide entry....Minus sign not in the correct position! " 
     ValidEntry = False 
     Exit For 
    End If 

    Case 46 ' Period 

    If ValidDecimal Then 'One has already been detected and this is a duplicate 
     ErrMsg = "Invalide entry....too many decimals!" 
     ValidEntry = False 
     Exit For 
    Else 
     ValidDecimal = True 
    End If 

    Case Else 
     ErrMsg = "Invalid numerical entry....Only digits 0-9 and the . + - characters are valid!" 
     ValidEntry = False 
     Exit For 

    End Select 

Next 

    If ValidEntry And ValidDigit Then 
     IsValidNumericEntry = True 
    Else 
     If ValidDigit = False Then 
      ErrMsg = "Text string contains an invalid numeric format." & vbCrLf _ 
      & "Use only one of the following formats!" & vbCrLf _ 
      & "(+dd.dd -dd.dd +dd -dd dd.d or dd)! " 
     End If 
     MsgBox (ErrMsg & vbCrLf & vbCrLf & "You Entered: " & MyString) 
     IsValidNumericEntry = False 
    End If 

End Function 

Function ConvertToLong(stringVal As String) As Long 
'Assumes the user has verified the string contains a valide numeric entry. 
'User should call the function IsValidNumericEntry first especially after any user input 
'to verify that the user has entered a proper number. 

ConvertToLong = CLng(stringVal) 


End Function 
Function ConvertToDouble(stringVal As String) As Double 
'Assumes the user has verified the string contains a valide numeric entry. 
'User should call the function IsValidNumericEntry first especially after any user input 
'to verify that the user has entered a proper number. 

    ConvertToDouble = CDbl(stringVal) 

End Function 

Answer 5

強制轉爲或轉換爲int，注意以下事項。

這些函數是Excel VBA中取決於系統區域設置的視圖函數之一。因此，如果您在歐洲某些國家/地區使用雙倍逗號，則會在美國遇到錯誤。

例如，在歐洲的Excel版本0.5將與CDbl（）表現良好，但在美國的版本，它會導致5 因此，我建議使用以下選擇：

Public Function CastLong(var As Variant) 

    ' replace , by . 
    var = Replace(var, ",", ".")   

    Dim l As Long 
    On Error Resume Next 
    l = Round(Val(var)) 

    ' if error occurs, l will be 0 
    CastLong = l 

End Function 

' similar function for cast-int, you can add minimum and maximum value if you like 
' to prevent that value is too high or too low. 
Public Function CastInt(var As Variant) 

    ' replace , by . 
    var = Replace(var, ",", ".") 

    Dim i As Integer 
    On Error Resume Next 
    i = Round(Val(var)) 

    ' if error occurs, i will be 0 
    CastInt = i 

End Function 

當然，你也可以考慮人們使用逗號和點的情況，例如三千如3,000.00。如果您需要這些類型的功能，那麼您必須檢查另一個解決方案。