項目找不到「查找」vba

Question

我在查找用戶ID列表。但是有些用戶不再存在。我試過test方法，on error go to方法和if err.number<> 0 then方法。我仍然收到Run-time error '91': object variable or with block variable not set。該號碼不存在於列表中。下面是我的代碼，有幾個沒有結果的嘗試

On Error GoTo errorLn 

If Err.Number <> 0 Then 
GoTo errorLn 
End If 
Cells.Find(What:=uSSO, After:=ActiveCell, LookIn:=xlFormulas, _ 
    LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
    MatchCase:=False, SearchFormat:=False).Select 

還有什麼其他的選擇？或者我錯誤地放錯了「錯誤」這一行？我試過它之前和之後的「cells.Find ...」

Answer 1

我相信你需要重新調整它只是一點點。這是不是最好的實踐與On Error Resume Next處理錯誤，但你可以試試這個：

On Error Resume Next 
Cells.Find(What:=uSSO, After:=ActiveCell, LookIn:=xlFormulas, _ 
    LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
    MatchCase:=False, SearchFormat:=False).Select 

If Err.Number <> 0 Then 
'''Do your error stuff''' 
GoTo errorLn 
Else 
    Err.Clear 
End If 

這是否工作，爲您的情況？

來源：http://www.mrexcel.com/forum/excel-questions/143988-check-if-value-exists-visual-basic-applications-array.html

Answer 2

試試這個

Sub Sample1() 
    Dim oSht As Worksheet 
    Dim uSSO As String 
    Dim aCell As Range 

    On Error GoTo Whoa 

    '~~> Change this to the relevant sheet 
    Set oSht = Sheets("Sheet1") 

    '~~> Set User ID here 
    uSSO = "User ID" 

    Set aCell = oSht.Cells.Find(What:=uSSO, LookIn:=xlFormulas, _ 
    LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
    MatchCase:=False, SearchFormat:=False) 

    '~~> Check if found or not 
    If Not aCell Is Nothing Then 
     MsgBox "Value Found in Cell " & aCell.Address 
    Else 
     MsgBox "Value Not found" 
    End If 

    Exit Sub 
Whoa: 
    MsgBox Err.Description 
End Sub 

我也建議閱讀此鏈接，我已經涵蓋.Find和.FindNext

主題：.Find和.FindNext在Excel VBA

鏈接：http://www.siddharthrout.com/2011/07/14/find-and-findnext-in-excel-vba/

Answer 3

你會想要做一些不同於有消息框的東西，據推測。

Dim myCell As Range 

Set myCell = Cells.Find(What:=uSSO, After:=ActiveCell, LookIn:=xlFormulas, _ 
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
MatchCase:=False, SearchFormat:=False) 

If (Not myCell Is Nothing) Then 
    MsgBox "something!" 

Else 
    MsgBox "nothing" 
End If 

Answer 4

只是爲了後人，這是你怎麼做沒有出錯處理（從：http://www.mrexcel.com/forum/excel-questions/519070-visual-basic-applications-error-handling-when-dealing-cells-find.html）。

Dim rngFound As Range 

Set rngFound = Sheets("WhateverSheet").UsedRange.Find(What:="SoughtValue",LookIn:=xlFormulas) 

If Not rngFound Is Nothing Then 
    'you found the value - do whatever 
Else 
    ' you didn't find the value 
End if