XSLT - 副本孫子們重新排序

Question

我對XSLT很陌生，我試圖複製一個現有的XML文件，我已經擁有但重新排序的元素，但是當我嘗試重新排列孫子時，我被卡住了。

比方說，我有這樣的輸入：

<grandParent> 
    <parent> 
     <c>789</c> 
     <b> 
      <b2>123</b2> 
      <b1>456</b1> 
     </b> 
     <a>123</a> 
    </parent> 
    .... 
</grandParent> 

我想要做的就是B = B1，B2中得到相同的XML文件，但改變標籤的順序爲A，B，C該訂單。 於是我開始用XSLT文件：

<xsl:template match="node()|@*"> <- This should copy everything as it is 
    <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 
<xsl:template match="grandParent/parent"> <- parent elements will copy in this order 
    <xsl:copy> 
     <xsl:copy-of select="@*"/> 
     <xsl:copy-of select="a"/> 
     <xsl:copy-of select="b"/> 
     <xsl:copy-of select="c"/> 
    </xsl:copy> 
</xsl:template> 

但 「XSL：複製的選擇=」 b 「的」 副本，因爲他們指定的元素（B2，B1）。 我試着使用另一個xsl：template作爲「grandParent/parent/b」，但沒有任何幫助。

也許我沒有做正確的方式......任何提示？

謝謝！

的解決方案 - 感謝尼爾斯

您的解決方案工作得很好尼爾斯，我只是定製的多一點，以適應在我目前的情況，其中「B」是可選的，並且標籤的名字可能不相關。 最後的代碼是這樣的：

<xsl:template match="node()|@*"> <- This should copy everything as it is 
    <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 
<xsl:template match="grandParent/parent"> <- parent elements will copy in this order 
    <xsl:copy> 
     <xsl:copy-of select="@*"/> 
     <xsl:copy-of select="a"/> 
        <xslt:if test="b"> 
         <b> 
         <xsl:copy-of select="b1"/> 
         <xsl:copy-of select="b2"/> 
         </b> 
        </xslt:if> 
     <xsl:copy-of select="b"/> 
     <xsl:copy-of select="c"/> 
    </xsl:copy> 
</xsl:template> 

Answer 1

我試圖用另一種XSL：模板 「祖父母/父母/ B」，但不會幫助。

既然你有一個身份模板，你應該使用<xsl:apply-templates>代替<xsl:copy-of>

<xsl:template match="node()|@*"> 
    <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 
<xsl:template match="grandParent/parent"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*"/> 
     <xsl:apply-templates select="a"/> 
     <xsl:apply-templates select="b"/> 
     <xsl:apply-templates select="c"/> 
    </xsl:copy> 
</xsl:template> 

現在你可以添加一個類似模板的b元素

<xsl:template match="parent/b"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*"/> 
     <xsl:apply-templates select="b1"/> 
     <xsl:apply-templates select="b2"/> 
    </xsl:copy> 
</xsl:template> 

這將很好地處理這種情況b不存在 - 如果select="b"沒有找到任何元素，則不會激發模板。

事實上，如果排序順序是在兩種情況下（按字母順序元素名）一樣，那麼您可以將兩個模板合併成一個，它使用<xsl:sort>，給人的

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:strip-space elements="*" /> 
    <xsl:output method="xml" indent="yes" /> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="grandParent/parent | parent/b"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*"/> 
     <xsl:apply-templates select="*"> 
     <xsl:sort select="name()" /> 
     </xsl:apply-templates> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

一個完整的轉型（爲您提供給您的示例XML實際上並不需要@*位，因爲XML不包含任何屬性，但如果在真實XML中有任何屬性，或者您添加了該屬性，它將不會造成任何傷害任何未來）。

Answer 2

使用xsl:sort。

以下代碼不在我的頭頂，可能無法正常工作;但它背後的想法應該清楚。

<xsl:template match="node()|@*"> <- This should copy everything as it is 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="grandParent/parent"> <- parent elements will copy in this order 
    <xsl:copy> 
    <xsl:copy-of select="@*"/> 
    <xsl:copy-of select="a"/> 
    <b> 
     <xsl:for-each select="b/*"> 
      <xsl:sort select="text()" /> 
      <xsl:copy-of select="." /> 
     </xsl:for-each> 
    </b> 
    <xsl:copy-of select="c"/> 
    </xsl:copy> 
</xsl:template> 

Answer 3

這裏是一個最通用的解決方案 - 使用xsl:sort和模板 - 沒有xsl:copy-of並沒有具體的名字的硬編碼：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="*/*"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*"/> 
     <xsl:apply-templates select="node()"> 
     <xsl:sort select="name()"/> 
     </xsl:apply-templates> 
    </xsl:copy> 
</xsl:template> 
</xsl:stylesheet> 

當這種變換所提供的XML文檔應用：

<grandParent> 
    <parent> 
     <c>789</c> 
     <b> 
      <b2>123</b2> 
      <b1>456</b1> 
     </b> 
     <a>123</a> 
    </parent> 
    .... 
</grandParent> 

想要的，正確的結果產生：

<grandParent> 
    <parent> 
     <a>123</a> 
     <b> 
     <b1>456</b1> 
     <b2>123</b2> 
     </b> 
     <c>789</c> 
    </parent> 
    .... 
</grandParent> 

現在，讓我們改變XML文檔中的所有名稱 - 請注意，沒有任何其他的答案可與此：

<someGrandParent> 
    <someParent> 
     <z>789</z> 
     <y> 
      <y2>123</y2> 
      <y1>456</y1> 
     </y> 
     <x>123</x> 
    </someParent> 
    .... 
</someGrandParent> 

我們應用相同改造和它再次產生正確的結果：

<someGrandParent> 
    <someParent> 
     <x>123</x> 
     <y> 
     <y1>456</y1> 
     <y2>123</y2> 
     </y> 
     <z>789</z> 
    </someParent> 
    .... 
</someGrandParent>