什麼是最好的VBA數據類型`key` =>`value`來保存與PHP數組相同的數據

Question

我正在使用VBA，並且需要將數據保存到key =>value以獲得最快速度;這種數據類型幫助我緩存來自http請求的響應文本，提高查詢速度。但我不知道最好的辦法是什麼？我需要一個與php數組類型相同的數據類型key=>value！感謝您的幫助！

Answer 1

你看過字典對象嗎？

Sub DictExample1() 

Dim dict As Dictionary 
Dim v As Variant 

    'Create the dictionary   
    Set dict = New Dictionary 

    'Add some (key, value) pairs 
    dict.Add "John", 34 
    dict.Add "Jane", 42 
    dict.Add "Ted", 402 

    'How many items do we have? 
    Debug.Print "Number of items stored: " & dict.Count 

    'We can retrieve an item based on the key 
    Debug.Print "Ted is " & dict.Item("Ted") & " years old" 


    'We can test whether an item exists 
    Debug.Print "We have Jane's age: " & dict.Exists("Jane") 
    Debug.Print "We have Zak's age " & dict.Exists("Zak") 

    'We can update a value by replacing it 
    dict.Item("Ted") = dict.Item("Ted")/10 

    Debug.Print "Ted's real age is: " & dict.Item("Ted") 

    'We can add more items 
    dict.Add "Carla", 23 

    'And we can iterate through the complete dictionary 
    For Each v In dict.Keys 
     Debug.Print "Name: " & v & "Age: "; dict.Item(v) 
    Next 

End Sub 

（來源：http://www.techbookreport.com/tutorials/vba_dictionary.html）