VB設置郵件優先級高

Question

該代碼發出的電子郵件和工作正常，但由於某種原因，它不會出去的重要性。我究竟做錯了什麼。

Option Explicit On 
Imports System.IO 
Imports System.Net.Mail 
Module SendMail 
Sub SendMessage() 
     Dim olApp As Object 
     Dim olMail As Object 
     Dim olNs As Object 
     Dim Priority As MailPriority 
    olApp = CreateObject("Outlook.Application") 
    olNs = olApp.GetNamespace("MAPI") 
    olMail = olApp.CreateItem(0) 

    With olMail 
     olMail.To = "" '// Add recipient 
     olMail.Cc = "" 
     olMail.Bcc = "" 
     olMail.Subject = "New File " 
     olMail.HTMLBody = "Your File is Ready " & Format(Now, "Long Date") 
     olMail.Attachments.Add = " " '// Add attachments to the message. 
     olMail.Priority = MailPriority.High '// High importance 
     olMail.Send() 
    End With 
    olMail = Nothing 
    olApp = Nothing 
    olNs = Nothing 
End Sub 
End Module 

Answer 1

嘗試使用System.Net.Mail命名空間來代替發送。

例子：

Option Strict On 
Option Explicit On 
Option Infer Off 
Imports System.Net.Mail 
Public Class Form1 
    Function SendEmail(ByVal Recipients As List(Of String), _ 
         ByVal FromAddress As String, _ 
         ByVal Subject As String, _ 
         ByVal Body As String, _ 
         ByVal UserName As String, _ 
         ByVal Password As String, _ 
         Optional ByVal Server As String = "smtp.gmail.com", _ 
         Optional ByVal Port As Integer = 587, _ 
         Optional ByVal Attachments As List(Of String) = Nothing) As String 
     Dim Email As New MailMessage() 
     Try 
      Dim SMTPServer As New SmtpClient 
      For Each Attachment As String In Attachments 
       Email.Attachments.Add(New Attachment(Attachment)) 
      Next 
      Email.From = New MailAddress(FromAddress) 
      For Each Recipient As String In Recipients 
       Email.To.Add(Recipient) 
      Next 
      Email.Subject = Subject 
      Email.Body = Body 
      '---------------------------------- 
      Email.Priority = MailPriority.High 
      '---------------------------------- 
      SMTPServer.Host = Server 
      SMTPServer.Port = Port 
      SMTPServer.Credentials = New System.Net.NetworkCredential(UserName, Password) 
      SMTPServer.EnableSsl = True 
      SMTPServer.Send(Email) 
      Email.Dispose() 
      Return "Email to " & Recipients(0) & " from " & FromAddress & " was sent." 
     Catch ex As SmtpException 
      Email.Dispose() 
      Return "Sending Email Failed. Smtp Error." 
     Catch ex As ArgumentOutOfRangeException 
      Email.Dispose() 
      Return "Sending Email Failed. Check Port Number." 
     Catch Ex As InvalidOperationException 
      Email.Dispose() 
      Return "Sending Email Failed. Check Port Number." 
     End Try 
    End Function 
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
     Dim Recipients As New List(Of String) 
     Recipients.Add("SomeEmailAddress") 
     Dim FromEmailAddress As String = Recipients(0) 
     Dim Subject As String = "Test From VB." 
     Dim Body As String = "email body text, if you are reading this from your gmail account, the program worked." 
     Dim UserName As String = "GMAIL USERNAME WITHOUT (@GMAIL>COM)" 
     Dim Password As String = "Password" 
     Dim Port As Integer = 587 
     Dim Server As String = "smtp.gmail.com" 
     Dim Attachments As New List(Of String) 
     MsgBox(SendEmail(Recipients, FromEmailAddress, Subject, Body, UserName, Password, Server, Port, Attachments)) 
    End Sub 
End Class 

Answer 2

從看MSDN documentation for Outlook 2013's MailItem class來看，似乎沒有Priority屬性（你想設置）。改爲嘗試設置the Importance property。

...或者如果您不需要Outlook功能，只想發送郵件，只需使用.NET自己的SmtpClient class發送郵件即可。