移動元素shortdesc

如何使用xslt變換在元素h1之後定位元素shortdesc。目前我通過以下代碼獲取每個元素的內容。移動元素shortdesc

<xsl:template match="shortdesc" mode="body">  
    <shortdesc> 
     <xsl:apply-templates mode="body"/> 
    </shortdesc> 
</xsl:template> 
<xsl:template match="p" mode="body">  
    <p> 
     <xsl:apply-templates mode="body"/> 
    </p> 
</xsl:template> 
<xsl:template match="h1" mode="body">  
    <h1> 
     <xsl:apply-templates mode="body"/> 
    </h1> 
</xsl:template>

源文件

<topic>  
    <h1>text</h1> 
    <p>text</p> 
    <p>text</p> 
    <shortdesc>text</shortdesc> 
    <p>text</p> 
    <p>text</p> 
</topic>

目標文件（它應該像這樣改造後）

<topic> 
    <h1>text</h1> 
    <shortdesc>text</shortdesc> 
    <p>text</p> 
    <p>text</p> 
    <p>text</p> 
    <p>text</p> 
</topic>

感謝您的想法

來源

2017-07-14 Olli

源文件必須具有某種原因你沒有向我們展示了一個根元素。您可以通過添加匹配根元素的模板並從那裏將模板按照您需要的順序應用到子節點來實現所需的順序。 –

對不起，我忘了他的根源。我已添加元素主題 – Olli

模板匹配'topic'在哪裏？ –

可以使用這樣的伎倆：

<xsl:template match="h1" mode="body">  
    <h1> 
     <xsl:apply-templates mode="body"/> 
    </h1> 
    <xsl:apply-templates select="../shortdesc" mode="desc"/> 
</xsl:template> 

<xsl:template match="shortdesc" mode="body"/> 
<xsl:template match="shortdesc" mode="desc">  
    <shortdesc> 
     <xsl:apply-templates mode="body"/> 
    </shortdesc> 
</xsl:template>

，並順便說一句，你不希望像這樣的東西給你更換模板：

<xsl:template match="*" mode="body"> 
    <xsl:element name="{name()}"> 
     <xsl:apply-templates mode="body"/> 
    </xsl:element> 
</xsl:template>

？

來源

2017-07-14 07:27:45

太複雜了。兩個都。 –

我不認爲使用顯式應用模板這是一個非常複雜的伎倆:) –

爲了簡化示例手邊的問題，考慮到以下輸入：

XML

<topic>  
    <h1>text</h1> 
    <p>text</p> 
    <p>text</p> 
    <shortdesc>text</shortdesc> 
    <p>text</p> 
    <p>text</p> 
</topic>

以下樣式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/topic">  
    <xsl:copy> 
     <xsl:apply-templates select="h1"/> 
     <xsl:apply-templates select="shortdesc"/> 
     <xsl:apply-templates select="p"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="h1 | shortdesc | p">  
    <xsl:copy> 
     <xsl:apply-templates/> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>

將返回：

結果

<?xml version="1.0" encoding="UTF-8"?> 
<topic> 
    <h1>text</h1> 
    <shortdesc>text</shortdesc> 
    <p>text</p> 
    <p>text</p> 
    <p>text</p> 
    <p>text</p> 
</topic>

來源

2017-07-14 08:05:39

移動元素shortdesc

回答

相關問題