什麼是從位圖數據獲取jpg的最簡單方法

Question

我需要將從影片剪輯抓取的bitmapData轉換爲jpeg或png。有沒有一些解釋？

Answer 1

看到這個例子中取一部分，其將字節的圖像，我已經給整個供您參考

package { 
    import encoding.JPGEncoder; 
    import flash.display.Bitmap; 
    import flash.display.BitmapData; 
    import flash.display.Loader; 
    import flash.display.Sprite; 
    import flash.utils.ByteArray; 
    import flash.events.Event 

    public class Converter extends Sprite { 

     [Embed(source = "image.jpg")] 
     private var image:Class 

     private const QUALITY:uint = 80; 

     public function Converter():void { 

      var bitmap:Bitmap = new image(); 
      var bitmapData:BitmapData = bitmap.bitmapData; 

      //encode BitmapData to JPG 
      var encoder:JPGEncoder = new JPGEncoder(QUALITY); 
      var rawBytes:ByteArray = encoder.encode(bitmap.bitmapData); 

      //decode JPG ByteArray back to BitmapData 
      var loader:Loader = new Loader(); 
      loader.contentLoaderInfo.addEventListener(Event.COMPLETE, getBitmapData) 
      loader.loadBytes(rawBytes); 
     } 

     private function getBitmapData(e:Event):void { 
      var decodedBitmapData:BitmapData = Bitmap(e.target.content).bitmapData 
      trace(decodedBitmapData); 
     } 
    } 
} 

Answer 2

這不是最簡單的方法，但根據您的圖像的尺寸，可能是值得一看。延斯·克勞斯編制jpeglib與鍊金術，它編碼速度遠遠超過的as3corelib的版本，甚至蒂博因貝特的改進AS3版本：

http://www.websector.de/blog/2009/06/21/speed-up-jpeg-encoding-using-alchemy/

Answer 3

現在，您可以使用內置到Flash Player 11.3和AIR 3.3的原生JPEG編碼。

var quality:int = 50; 
var bounds:Rectangle = bitmapData.rect; 
var result:ByteArray = bitmapData.encode(bounds, new JPEGEncoderOptions(50)); 

這需要-swf-version=16被傳遞到編譯器。