用列文本替換文本標記

Question

我有幾列文本。此外，我有一個專欄，名爲Replacement text。此列包含其中有標記的字符串，如[1], [2], etc.

我想用標記行中的文本替換標記。

例如，Here you can find [5]變得Here you can find b，因爲[5]是標記列和字符串b的行中是用於標記物的價值。

我正在考慮創建一個大的if-else結構和substitute文本，這是非常容易出錯的。

但是，我懇請問您是否有更簡單的解決方案？

我感謝您的意見！

Answer 1

ReplaceBrackets1：使用RegEx提取列號。處理100K記錄需要15.03秒。

---

Sub ReplaceBrackets1() 
    'http://analystcave.com/excel-regex-tutorial/ 
    Dim c As Range 
    Dim Match As Object, Matches As Object, regex As Object 
    Set regex = CreateObject("VBScript.RegExp") 

    With regex 
     .Global = True 
     .Pattern = "\[(.*?)\]" 
    End With 

    For Each c In Range("K3", Range("K" & Rows.Count).End(xlUp)) 
     If regex.Test(c.Text) Then 
      Set Matches = regex.Execute(c.Text) 
      For Each Match In Matches 
       c.Replace Match, c.EntireRow.Columns(CInt(Match.SubMatches(0))) 
      Next Match 

     End If 
    Next 
End Sub 

ReplaceBrackets2：loades數據到陣列，使用正則表達式提取的列數和只寫工作表1時間。處理100K記錄需要1.27秒。

---

Sub ReplaceBrackets2() 
'http://analystcave.com/excel-regex-tutorial/ 
    Dim x As Long, column As Long 
    Dim arData, values 
    Dim Match As Object, Matches As Object, regex As Object 
    Set regex = CreateObject("VBScript.RegExp") 

    With regex 
     .Global = True 
     .Pattern = "\[(.*?)\]" 
    End With 

    values = Range("K3", Range("K" & Rows.Count).End(xlUp)) 
    arData = Range("A3", "L" & UBound(values, 1) + 2) 

    For x = 1 To UBound(values, 1) 
     If regex.Test(values(x, 1)) Then 
      Set Matches = regex.Execute(values(x, 1)) 
      For Each Match In Matches 
       column = Match.SubMatches(0) 
       values(x, 1) = arData(x, column) 
      Next Match 
     End If 
    Next 

    Range("K3", Range("K" & Rows.Count).End(xlUp)) = values 

End Sub 

轉換ReplaceBrackets1爲UDF（getReplacedText）後，我驚訝地發現，只用了2.53秒填寫爲100K記錄的配方。我不知道這樣做會比原來快。但擁有這麼多公式確實會減慢電子表格的速度。

getReplacedText：使用靜態RegEx解析數據。

Function getReplacedText(ReplacementText As String, Source As Range) 
'http://analystcave.com/excel-regex-tutorial/ 
    Dim Match As Object, Matches As Object 
    Static regex As Object 
    If regex Is Nothing Then 
     Set regex = CreateObject("VBScript.RegExp") 

     With regex 
      .Global = True 
      .Pattern = "\[(.*?)\]" 
     End With 
    End If 

    If regex.Test(ReplacementText) Then 
     Set Matches = regex.Execute(ReplacementText) 
     For Each Match In Matches 
      ReplacementText = Replace(ReplacementText, Match, Source.Columns(CInt(Match.SubMatches(0)))) 
     Next Match 

    End If 

    getReplacedText = ReplacementText 
End Function 

Answer 2

這個答案是非常托馬斯Inzina的他的回答的第一個版本的抄襲，但執行更換一個很簡單的辦法是：

Sub ReplaceText() 
    Dim r As Long 
    Dim c As Long 
    With ActiveSheet 
     For r = 3 To .Range("K" & .Rows.Count).End(xlUp).Row 
      For c = 1 To 10 
       .Cells(r, "K").Replace "[" & c & "]", .Cells(r, c).Value 
      Next 
     Next 
    End With 
End Sub 

上面的代碼將嘗試使用做了替換全部十個列。

正如托馬斯指出，下面的代碼將只做替換如果替換是必要的，因此可能是一個數量級的速度更快，所以無疑是一個更好的解決方案：

Sub ReplaceText() 
    Dim r As Long 
    Dim c As Long 
    With ActiveSheet 
     For r = 3 To .Range("K" & .Rows.Count).End(xlUp).Row 
      For c = 1 To 10 
       If Instr(.Cells(r, "K").Value, "[" & c & "]") > 0 Then 
        .Cells(r, "K").Replace "[" & c & "]", .Cells(r, c).Value 
       End If 
      Next 
     Next 
    End With 
End Sub 

（非常感謝托馬斯努力在兩種不同的方法上進行速度測試。）