中的XML解析標籤與XSL

Question

我有這樣一個xml：

<node> 
    <par> 
     Lorem ipsum dolor <bold>sit</bold> amet, consectetur adipiscing elit. 
    <par> 
</node> 

我必須打印這樣一個html：

<p> 
    <span>Lorem ipsum dolor</span> 
    <span class="bolder">sit</span> 
    <span>amet, consectetur adipiscing elit.</span> 
</p> 

我無法找到一個方法來截斷由文本中間bold標記並添加新標記

Answer 1

以下轉化，當施加到所提供的輸入，產生您所要求的結果。

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy><xsl:apply-templates select="@*|node()" /></xsl:copy> 
    </xsl:template> 

    <xsl:template match="node"> 
     <xsl:apply-templates /> 
    </xsl:template> 

    <xsl:template match="par"> 
     <p><xsl:apply-templates /></p> 
    </xsl:template> 

    <xsl:template match="par/text()"> 
     <span><xsl:copy-of select="." /></span> 
    </xsl:template> 

    <xsl:template match="bold"> 
     <span class="bolder"><xsl:value-of select="." /></span> 
    </xsl:template> 
</xsl:transform> 

Answer 2

您可以使用text()選擇器並將其索引到內部元素的任意一側，以達到您想要的效果。因此，對於'Lorem ipsum dolor'選擇時的par上下文將是text()[1]和'amet, consectetur adipiscing elit.'將text()[2]

Answer 3

以下XSLT樣式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" /> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node"> 
    <xsl:apply-templates/> 
    </xsl:template> 

    <xsl:template match="par"> 
    <p> 
     <xsl:apply-templates /> 
    </p> 
    </xsl:template> 

    <xsl:template match="text()"> 
    <span> 
     <xsl:value-of select="normalize-space(.)"/> 
    </span> 
    </xsl:template> 

    <xsl:template match="bold/text()"> 
    <span class="bolder"> 
     <xsl:value-of select="normalize-space(.)"/> 
    </span> 
    </xsl:template> 

</xsl:stylesheet> 

當施加到該輸入XML：

<node> 
    <par> 
    Lorem ipsum dolor <bold>sit</bold> amet, consectetur adipiscing elit. 
    </par> 
</node> 

產生以下輸出：

<p> 
    <span>Lorem ipsum dolor</span> 
    <span class="bolder">sit</span> 
    <span>amet, consectetur adipiscing elit.</span> 
</p>