VBA從Excel中提取系列名稱，X和Y值圖表

Question

我一直在尋找從Excel圖表中提取數據的幫助。具體而言，我需要從圖表上所有點拉系列名稱,X和Y。我從Excel的基本代碼開始，但它只給我X值。

Sub GetChartValues() 
Dim NumberOfRows As Integer 
Dim X As Object 
Counter = 2 

' Calculate the number of rows of data. 
NumberOfRows = UBound(ActiveChart.SeriesCollection(1).Values) 

Worksheets("ChartData").Cells(1, 1) = "X Values" 

' Write x-axis values to worksheet. 
With Worksheets("ChartData") 
    .Range(.Cells(2, 1), _ 
    .Cells(NumberOfRows + 1, 1)) = _ 
    Application.Transpose(ActiveChart.SeriesCollection(1).XValues) 
End With 

' Loop through all series in the chart and write their values to 
' the worksheet. 
For Each X In ActiveChart.SeriesCollection 
    Worksheets("ChartData").Cells(1, Counter) = X.Name 

    With Worksheets("ChartData") 
    .Range(.Cells(2, Counter), _ 
    .Cells(NumberOfRows + 1, Counter)) = _ 
    Application.Transpose(X.Values) 
    End With 

    Counter = Counter + 1 
Next 

End Sub 

我需要弄清楚如何使這項工作，所以我可以創建給定的值的表。我還附上了我正在處理的圖表的圖像。任何幫助真的會很感激！

Answer 1

給這個一去，請確保您的圖表選擇運行的代碼之前：

Sub Getting_data() 

    Dim iSrs As Long 
    Dim cht As Chart 
    Dim srs As Series 
    Dim wkst As Worksheet 

    If ActiveChart Is Nothing Then Exit Sub 

    Set cht = ActiveChart 
    Set wkst = Worksheets.Add 
    For iSrs = 1 To cht.SeriesCollection.Count 
     Set srs = cht.SeriesCollection(iSrs) 
     On Error Resume Next 
     wkst.Cells(1, 2 * iSrs).value = srs.Name 
     wkst.Cells(2, 2 * iSrs - 1).Resize(srs.Points.Count).value = _ 
      WorksheetFunction.Transpose(srs.XValues) 
     wkst.Cells(2, 2 * iSrs).Resize(srs.Points.Count).value = _ 
      WorksheetFunction.Transpose(srs.Values) 
    Next 

End Sub