在VBScript中排序多維數組

Question

如何根據孔大小參數對多維數組進行「排序」？

例如：一個簡單的例子是（從文本文件中加載）：

> Liv1.HoleSize[0] = 22 Liv1.HoleX[0] = 250 Liv1.HoleY[0] = -55 
> Liv1.HoleSize[1] = 14 Liv1.HoleX[1] = 750 Liv1.HoleY[1] = 0 
> Liv1.HoleSize[2] = 22 Liv1.HoleX[2] = 900 Liv1.HoleY[2] = -55 

則必然導致：

> Liv1.HoleSize[0] = 14 Liv1.HoleX[0] = 750 Liv1.HoleY[0] = 0 
> Liv1.HoleSize[1] = 22 Liv1.HoleX[1] = 250 Liv1.HoleY[1] = -55 
> Liv1.HoleSize[2] = 22 Liv1.HoleX[2] = 900 Liv1.HoleY[2] = -55 

Answer 1

如VBScript沒有本機排序，你就必須推出你自己分類，或者從朋友那裏得到一點幫助。

如果你的任務是要排序的輸入文件（逐字給出），以指定順序的輸出文件，sort.exe是你的朋友：

Dim sIn : sIn = "..\data\in00.txt" 
    WScript.Echo readAllFromFile(sIn) 
    WScript.Echo "-----------" 
    Dim sCmd : sCmd = "sort /+19 " & qq(resolvePath(sIn)) 
    Dim aRet : aRet = goWSLib.Run(sCmd) 
    If aRet(0) Then 
    ' handle error 
    Else 
    WScript.Echo aRet(2) 
    End If 

輸出：

================================================================ 
Liv1.HoleSize[0] = 22 Liv1.HoleX[0] = 250 Liv1.HoleY[0] = -55 
Liv1.HoleSize[1] = 14 Liv1.HoleX[1] = 750 Liv1.HoleY[1] = 0 
Liv1.HoleSize[2] = 22 Liv1.HoleX[2] = 900 Liv1.HoleY[2] = -55 

----------- 
Liv1.HoleSize[1] = 14 Liv1.HoleX[1] = 750 Liv1.HoleY[1] = 0 
Liv1.HoleSize[0] = 22 Liv1.HoleX[0] = 250 Liv1.HoleY[0] = -55 
Liv1.HoleSize[2] = 22 Liv1.HoleX[2] = 900 Liv1.HoleY[2] = -55 

================================================================ 

如果某樣東西像這樣可以解決你的問題，就這麼說，我們可以在庫函數中討論支持代碼。

但是，如果你（要）解析（d）輸入文件轉換成二維數組，你可以得到的最好的朋友是一個disconnectes ADODB記錄：

Dim aData : aData = Split(Join(Array(_ 
      "22 250 -55" _ 
     , "14 750 0" _ 
     , "22 900 -55" _ 
     , "11 222 333" _ 
))) 
    Dim afData(3, 2) 
    Dim nRows : nRows = UBound(afData, 1) 
    Dim nCols : nCols = UBound(afData, 2) 
    Dim i, r, c 
    For i = 0 TO UBound(aData) 
     r = i \ nRows 
     c = i Mod (nCols + 1) 
     afData(r, c) = aData(i) 
'  WScript.Echo i, r, c, aData(i) 
    Next 
    For r = 0 To nRows 
     For c = 0 To nCols 
      WScript.StdOut.Write vbTab & afData(r, c) 
     Next 
     WScript.Echo 
    Next 
    WScript.Echo "-----------------" 
    Dim oRS : Set oRS = CreateObject("ADODB.Recordset") 
    For c = 0 To nCols 
     oRS.Fields.Append "Fld" & c, adInteger 
    Next 
    oRS.Open 
    For r = 0 To nRows 
     oRS.AddNew 
     For c = 0 To nCols 
      oRS.Fields(c).value = afData(r, c) 
     Next 
     oRS.UpDate 
    Next 
    oRS.Sort = "Fld0" 
    WScript.Echo oRS.GetString(adClipString, , vbTab, vbCrLf) 
    WScript.Echo "-----------------" 
    oRS.Sort = "Fld2" 
    WScript.Echo oRS.GetString(adClipString, , vbTab, vbCrLf) 

輸出：

======================================== 
     22  250  -55 
     14  750  0 
     22  900  -55 
     11  222  333 
----------------- 
11  222  333 
14  750  0 
22  250  -55 
22  900  -55 

----------------- 
22  250  -55 
22  900  -55 
14  750  0 
11  222  333 

======================================== 

再說一遍：如果看起來很有希望，我們可以討論如何根據您的需求調整/簡化概念驗證代碼。