JSON對象到一個DataTable和一個字符串

Question

我已經在asp.net通過HTTP POST收到以下JSON：

{ 
"Header": { 
    "MCC": "415", 
    "F0": "0", 
    "REG ID": "0" 
}, 
"Contacts": [ 
    { 
     "name": "jocelyne", 
     "mo": "jocelyne" 
    }, 
    { 
     "name": "eliane", 
     "mo": "12345678" 
    } 
] 
} 

我只需要把數據在接觸中的DataTable和反序列化在報頭中的數據到3個變量...

我想這：

Dim deserializedProduct As List(Of Dictionary(Of String, String)) = JsonConvert.DeserializeObject(Of List(Of Dictionary(Of String, String)))(json) 

這：

Dim table As DataTable = JsonConvert.DeserializeObject(Of DataTable)(json) 

我嘗試使用此JSON：

{ 
"Data": [ 
    { 
     "MCC": "415", 
     "F0": "0", 
     "REG ID": "0" 
    } 
], 
"Contacts": [ 
    { 
     "name": "jocelyne", 
     "mo": "jocelyne" 
    }, 
    { 
     "name": "eliane", 
     "mo": "12345678" 
    } 
] 
} 

但這些都不工作...

Answer 1

一種方法是創建的數據相匹配，你收到了一些類：

Class Data 
    Public Header As Header 
    Public Contacts As List(Of Contact) 
End Class 

<System.Runtime.Serialization.DataContract> 
Class Header 
    <System.Runtime.Serialization.DataMember(Name := "MCC")> 
    Public MCC As Integer 
    <System.Runtime.Serialization.DataMember(Name := "F0")> 
    Public F0 As Integer 
    <System.Runtime.Serialization.DataMember(Name := "REG ID")> 
    Public RegId As Integer 
End Class 

Class Contact 
    Public Name As String 
    Public Mo As String 
End Class 

所以很容易對數據進行反序列化：

Sub Main 
    Dim json As String = <json> 
         { 
         "Header": { 
          "MCC": "415", 
          "F0": "0", 
          "REG ID": "0" 
         }, 
         "Contacts": [ 
          { 
           "name": "jocelyne", 
           "mo": "jocelyne" 
          }, 
          { 
           "name": "eliane", 
           "mo": "12345678" 
          } 
         ] 
         }</json>.Value 


    Dim data As Data = JsonConvert.DeserializeObject(Of Data)(json) 
    data.Dump() 
End Sub 

現在您可以輕鬆訪問諸如data.Header.MCC等

請注意，我這裏用DataContract/DataMember在Header類，你要尋找的值，否則解串器也沒辦法知道REG ID應映射到RegId（因爲在VB.Net中不能有空格的成員名稱）。

如果你真的想爲您的聯繫人DataTable，只是聲明Data.Contacts爲DataTable：

Class Data 
    Public Header As Header 
    Public Contacts As DataTable 
End Class