如何添加從一個目錄複製到另一個目錄中增加的文件夾中的文件

Question

我正在製作一個批處理文件，該文件複製我的Google書籤並將其粘貼到名爲「書籤備份」的另一個文件夾（有點像備份） 。我想在每天結束的時候讓腳本每天運行一次，這樣我總是可以備份（可以使其成爲一項計劃任務），因此我插入了一個命令來創建一個新文件夾（在稱爲備份的文件夾內部的書籤）稱爲「備份」，並在每次腳本運行時將其增加「1」（例如：backup1; backup2;等等）。我需要幫助獲取我剛剛複製的文件並將其粘貼到遞增的文件夾中。這是腳本，它複製和增加文件夾，但我不知道如何使複製的文件進入遞增的文件夾。

::this script backs up your Chrome bookmarks. 
::Checks to see if the folder exits and makes a new folder incremented by 1 

@echo off 
setlocal enableDelayedExpansion 
set "baseName=Backup" 
set "n=0" 
for /f "delims=" %%F in (
    '2^>nul dir /b /ad "%baseName%*."^|findstr /xri "%baseName%[0-9]*"' 
) do (
    set "name=%%F" 
    set "name=!name:*%baseName%=!" 
    if !name! gtr !n! set "n=!name!" 
) 
set /a n+=1 
md "%baseName%%n%" 


xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks" "C:\Users\jnicholas\Desktop\backup of bookmarks\" 
pause 

xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks.bak" "C:\Users\jnicholas\Desktop\backup of bookmarks" 
pause 

move /y | /-y "C:\Users\jnicholas\Desktop\backup of bookmarks\bookmarks" "C:\Users\jnicholas\Desktop\backup of bookmarks\"%baseName%%n%"" 

Answer 1

我會建議使用時間戳而不是順序編號。這裏也是一個命令中的一切，它是用戶獨立的。

@xcopy "%LocalAppData%\Google\Chrome\User Data\Default\bookmarks*" "%UserProfile%\Desktop\Backup of Bookmarks\%Date:~10,4%-%Date:~4,2%-%Date:~7,2%\" /I /Y 

這兩個bookmarks和bookmarks.bak文件複製到帶有時間戳的文件夾的書籤文件夾的備份中。

Answer 2

如果您使用XP Pro或更高版本，則會爲您的備份創建一個日期和時間戳文件夾。日期和時間格式與PC上的本地區域設置無關。

@echo off 
for /f "delims=" %%a in ('wmic OS Get localdatetime ^| find "."') do set dt=%%a 
set datestamp=%dt:~0,8% 
set timestamp=%dt:~8,6% 
set YYYY=%dt:~0,4% 
set MM=%dt:~4,2% 
set DD=%dt:~6,2% 
set HH=%dt:~8,2% 
set Min=%dt:~10,2% 
set Sec=%dt:~12,2% 

set stamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec% 
echo stamp: "%stamp%" 
echo datestamp: "%datestamp%" 
echo timestamp: "%timestamp%" 

xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks" "C:\Users\jnicholas\Desktop\backup of bookmarks\%stamp%\" 

xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks.bak" "C:\Users\jnicholas\Desktop\backup of bookmarks\%stamp%\" 
pause