XSLT匹配模板更改屬性只是一次

Question

我有與它的價值需要，只要它的值爲零，要更新的特定屬性（身份識別碼）的文件。該文件看起來像這樣

<?xml version="1.0" encoding="UTF-8"?><Summary> 
<Section myId="0"> 
    <Section myId="0"> 
    <Para>...</Para> 
    </Section> 
    <Section myId="5"> 
    <Para>...</Para> 
    </Section> 
</Section> 
</Summary> 

我使用的模板，以便將其設置爲從調用程序通過一個唯一的ID匹配的屬性，身份識別碼，但我只是想匹配文檔中的屬性之一。任何值爲零的附加屬性都將通過傳遞不同的ID進行更新。 我的模板，我使用的是這個樣子的：

<xsl:template  match = '@myId[.="0"]'> 
    <xsl:attribute name = "{name()}"> 
    <xsl:value-of select = "$addValue"/> 
    </xsl:attribute> 
</xsl:template> 

值的addValue是從調用程序通過一個全局參數。 我已經搜索了一天中很大一部分的答案，但是我無法僅將該模板應用一次。輸出將使用addValue的內容替換myId值。 我嘗試過匹配'@myId [。「0」] [1]「，我嘗試使用position（）函數進行匹配，但我的模板總是應用於所有myId爲零的屬性。

是否有可能適用的匹配模板只有一次？

Answer 1

是否有可能適用的匹配模板只有一次？

是：

1. 無論模板施加或不取決於導致執行要選擇的模板中的xsl:apply-templates。

2. Additionaly，匹配模式可以在保證了模板匹配的文件只在一個特定節點的方式來指定。

這裏是你可以做什麼：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="pNewIdValue" select="9999"/> 


<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match= 
"Section 
    [@myId = 0 
    and 
    not((preceding::Section | ancestor::Section) 
       [@myId = 0] 
     ) 
    ]/@myId"> 
    <xsl:attribute name="myId"><xsl:value-of select="$pNewIdValue"/></xsl:attribute> 
</xsl:template> 
</xsl:stylesheet> 

當這種轉化應用到所提供的XML文檔：

<Summary> 
    <Section myId="0"> 
     <Section myId="0"> 
      <Para>...</Para> 
     </Section> 
     <Section myId="5"> 
      <Para>...</Para> 
     </Section> 
    </Section> 
</Summary> 

想要的，正確的結果是製作：

<Summary> 
    <Section myId="9999"> 
     <Section myId="0"> 
     <Para>...</Para> 
     </Section> 
     <Section myId="5"> 
     <Para>...</Para> 
     </Section> 
    </Section> 
</Summary>