VBA - 我想刪除位於單元格頂部的按鈕 - 掃雷遊戲

Question

正如標題所示，我想刪除給定單元格位置的單元格頂部的按鈕。

這是我迄今爲止沒有成功嘗試過的。

Dim r As Range 'range is already given from another function call 
Dim butns As button 
With Sheet1.Buttons 
    butns.Top = r.Top 
    butns.Left = r.Left 
    End With 
Sheet1.Buttons(butns).Delete 

我的嘗試將獲取單元格的「頂部」和「左側」值，並找到與該值關聯的按鈕，然後將其刪除。

任何幫助將不勝感激。謝謝！

Answer 1

我認爲真正能夠找到哪個按鈕位於單元格頂部的唯一方法是查看按鈕的中心是否包含在單元格的維度中。

Dim r As Range 
Dim s As Shape 
Dim i As Long 
Dim cx As Double, cy As Double 

For i = 1 To Sheet1.Shapes.Count 
    Set s = Sheet1.Shapes(i) 
    cx = s.Left + s.Width/2 
    cy = s.Top + s.Height/2 
    If cx >= r.Left And cx <= r.Left + r.Width And _ 
     cy >= r.Top And cy <= r.Top + r.Height _ 
    Then 
     s.Delete 
     Exit For 
    End If 
Next 

Answer 2

這是形式的控制按鈕 - user3221162 13分鐘前

這是你想什麼呢？

注意在形狀循環時，確定.Type和.FormControlType以確保您只刪除表單按鈕控件，否則它將刪除符合條件的任何形狀，這一點很重要。

Option Explicit 

Sub Sample() 
    Dim ws As Worksheet 
    Dim shp As Shape 

    '~~> Change this to the relevant worksheet 
    Set ws = ThisWorkbook.Sheets("Sheet1") 

    '~~> Loop through shapes 
    For Each shp In ws.Shapes 
     '~~> Check if it is a form control 
     If shp.Type = 8 Then 
      '~~> Check if it is a button 
      If shp.FormControlType = xlButtonControl Then 
       '~~> Check the cell. Taking B2 as example 
       If shp.TopLeftCell.Address = "$B$2" Then shp.Delete 
      End If 
     End If 
    Next 
End Sub 

Answer 3

我建議你把形狀的名字（Button_1_1，Button_2_1等）的一些信息，然後在需要的時候打出了COORDS。由此你可以跟蹤哪個按鈕被放置在創建的地方。

座標轉換通常比預期更棘手。你需要關心縮放，DPI和其他東西。