perl的分裂3號線]用正則表達式

Question

我有這樣一行：
[Fri Oct 5 09:11 2012] 0.005 [ext2/1/rel 322 (0,50)] [abc] I'm Sure [he/she] is leading CORN @types (countyfair)

我如何從3]分裂，並有2個部分：

[Fri Oct 5 09:11 2012] 0.005 [ext2/1/rel 322 (0,50)] [abc]  

和

I'm Sure [he/she] is leading CORN @types (countyfair) 

Answer 1

這一個跳過三個] s：

use strict; 
use warnings; 

while (<>) { 
    if (my ($p1, $p2) = (/([^]]+][^]]+][^]]+])\s*(.*)/)) { 
    print "$p1 : $p2\n"; 
    } 
} 

使用數組：

my @a; 
while (<>) { 
    if (@a = (/([^]]+][^]]+][^]]+])\s*(.*)/)) { 
    print join(",", @a), "\n"; 
    } 
} 

Answer 2

我感興趣的是一個通用的功能，所以在這裏它是：

#!/usr/bin/env perl 

use strict; 
use warnings; 

my $str = q{[Fri Oct 5 09:11 2012] 0.005 [ext2/1/rel 322 (0,50)] [abc] I'm Sure [he/she] is leading CORN @types (countyfair)}; #'# fix highlight 

my ($first, $second) = split_after_nth(qr/]/, $str, 3); 
$second =~ s/^\s*//; #/# fix highlight 
print "$first\n$second\n"; 

sub split_after_nth { 
    my ($qr, $str, $num) = @_; 
    my @parts = split /($qr)/, $str, ++$num; 
    my $second = pop @parts; 
    my $first = join '', @parts; 
    return ($first, $second); 
} 

Answer 3

一看，後面的三串各由]終止會做訣竅。在第三個]之後，你沒有提到你想處理的空白，所以我把它留在了那裏。

use strict; 
use warnings; 

my $s = q{[Fri Oct 5 09:11 2012] 0.005 [ext2/1/rel 322 (0,50)] [abc] I'm Sure [he/she] is leading CORN @types (countyfair)}; 
my @pair = split /(?:[^]]*\]){3}\K/, $s; 

print "$_\n" for @pair; 

輸出

[Fri Oct 5 09:11 2012] 0.005 [ext2/1/rel 322 (0,50)] [abc] 
I'm Sure [he/she] is leading CORN @types (countyfair)