減半空格的數量在Vim的

Question

每一行的開頭誰能告訴我如何做到這一點的映射相反在Vim中：

nnoremap <leader>iw :let _s=@/<Bar>:let _s2=line(".")<Bar>:%s/^\s*/&&/ge<Bar>:let @/=_s<Bar>:nohl<Bar>exe ':'._s2<CR> 

由於澄清，這種映射雙打（&&部分）的數量在每行開始處的空格。 只有第一個常規字符之前的空格纔會受到影響。 保留當前搜索字符串（變量_s）。 此轉換後位置恢復（變量_s2）

所以基本上我正在尋找一個映射，如果它們被一個接一個地執行，將會撤銷這個映射。

我在計算如何限制這個新操作只能在第一個常規字符之前的空格上工作時遇到了問題。

Answer 1

下面的替代命令反轉其對應 加倍前導空格的效果。

:%s/^\(\s*\)\1/\1/ 

映射到被構造爲這個命令需要遵循相同 圖案如問題語句中使用（除了 取代來執行，當然）之一。爲了減少 定義重複，一個可以將狀態保持代碼分離成小 功能：

nnoremap <silent> <leader>> :call Preserve('%s/^\s*/&&/')<cr> 
nnoremap <silent> <leader><lt> :call Preserve('%s/^\(\s*\)\1/\1/')<cr> 
function! Preserve(cmd) 
    let [s, c] = [@/, getpos('.')] 
    exe a:cmd 
    let @/ = s 
    call setpos('.', c) 
endfunction 

Answer 2

你原有的替換是這樣（我與#的可讀性取代/分隔符）：

%s#^\s*#&&# 

這裏是我提出的反替代（深呼吸......）：

%s#^\s*#\=matchstr(submatch(0),'^.\{'.string(float2nr(len(submatch(0))/2)).'\}')# 

比方說，匹配的字符串（submatch(0)）包含n空白字符。我正在做的是計算這個數字的一​​半（n/2 = string(float2nr(len(submatch(0))/2))），然後從匹配中提取很多字符（基本上是matchstr(n/2)）。這確保我們獲得剛剛開始的空白的一半（可能是空格和製表符的混合）。

如果你知道的空白將只包含空格或ONLY選項卡，這可能有所簡化，例如：

%s#^\s*#\=repeat(" ",indent(".")/2)# 

在另一方面，我會建議重新擬定您的地圖，使他們更具可讀性，因此更容易修改和維護。我的方法是定義了兩個功能：

function! DoubleWS() 
    let pos = getpos('.') 
    let reg = getreg('@') 
    exe '%s/^\s*/&&/e' 
    call setreg('@',reg) 
    call setpos('.',pos) 
endfunction 

function! HalfWS() 
    let pos = getpos('.') 
    let reg = getreg('@') 
    exe '%s#^\s*#\=matchstr(submatch(0),"^.\\{".string(float2nr(len(submatch(0))/2))."\}")#e' 
    call setreg('@',reg) 
    call setpos('.',pos) 
endfunction 

注意，get/setpos/reg功能是保持光標位置並註冊的一個更可靠的方法。然後，您可以根據需要映射這些功能：

nnoremap <silent> <leader>iw :call DoubleWS()<CR> 
nnoremap <silent> <leader>rw :call HalfWS()<CR> 

希望有所幫助！