你可以做這樣的事情(如低內存佔用率超過代碼簡潔更重要):
const
MaxBufferSize = 16; // the largest size you actually need, in this example sizeof(TMyData_04)...
type
TMyData = packed record
TypeID: Byte;
Buffer: array[0..MaxBufferSize-1] of Byte;
end;
PMyData_01 = ^TMyData_01;
TMyData_01 = packed record
Data: Integer;
end;
PMyData_02 = ^TMyData_02;
TMyData_02 = packed record
Data: String;
end;
PMyData_03 = ^TMyData_03;
TMyData_03 = packed record
Data: TDateTime;
Index: Integer;
end;
PMyData_04 = ^TMyData_04;
TMyData_04 = packed record
Data: TDateTime;
Value: Real;
end;
...
然後,您可以分配TMyData
實例的數組到需要的長度,並呼籲System.Initialize()
初始化
var
Arr: array of TMyData;
SetLength(Arr, ...);
//...
Arr[Index].TypeID := $01;
System.Initialize(PMyData_01(@Arr[Index].Buffer)^);
// populate PMyData_01(@Arr[Index].Buffer)^ fields as needed...
// and so on ...
不要忘記調用上的項目System.Finalize()
重新分配前陣,以避免任何內存泄漏:
包含編譯器管理的數據類型的任何項目
var
I: Integer;
begin
for I := Low(Arr) to High(Arr) do
begin
case Arr[I].TypeID of
$01: System.Finalize(PMyData_01(@Arr[i].Buffer)^);
$02: System.Finalize(PMyData_02(@Arr[i].Buffer)^);
$03: System.Finalize(PMyData_03(@Arr[i].Buffer)^);
$04: System.Finalize(PMyData_04(@Arr[i].Buffer)^);
// and so on ...
end;
end;
end;
不理想,但它是功能...
泛型掛羊頭賣狗肉的一點點,你可以清理一下代碼:
const
MaxBufferSize = 16; // the largest size you actually need, in this example sizeof(TMyData_04)...
type
TMyDataHelper<T: record> = record
type PtrType = ^T;
class function GetDataTypeID: Byte; static;
end;
TMyData = packed record
TypeID: Byte;
Buffer: array[0..MaxBufferSize-1] of Byte;
procedure InitializeBuffer<T: record>;
procedure FinalizeBuffer;
procedure SetBufferData<T: record>(const NewData: T);
function BufferAs<T: record>: TMyDataHelper<T>.PtrType;
end;
TMyData_01 = packed record
Data: Integer;
end;
TMyData_02 = packed record
Data: String;
end;
TMyData_03 = packed record
Data: TDateTime;
Index: Integer;
end;
TMyData_04 = packed record
Data: TDateTime;
Value: Real;
end;
// and so on ...
class function TMyDataHelper<T>.GetDataTypeID: Byte;
begin
if TypeInfo(T) = TypeInfo(TMyData_01) then
Result := $01
else
if TypeInfo(T) = TypeInfo(TMyData_02) then
Result := $02
else
if TypeInfo(T) = TypeInfo(TMyData_03) then
Result := $03
else
if TypeInfo(T) = TypeInfo(TMyData_04) then
Result := $04
// and so on ...
else
Result := $00;
end;
procedure TMyData.InitializeBuffer<T>;
var
LTypeID: Byte;
begin
LTypeID := TMyDataHelper<T>.GetDataTypeID;
if TypeID <> LTypeID then
begin
FinalizeBuffer;
System.Initialize(BufferAs<T>^);
TypeID := LTypeID;
end;
end;
procedure TMyData.FinalizeBuffer;
begin
case TypeID of
$01: Finalize(BufferAs<TMyData_01>^);
$02: Finalize(BufferAs<TMyData_02>^);
$03: Finalize(BufferAs<TMyData_03>^);
$04: Finalize(BufferAs<TMyData_04>^);
// and so on ...
else
FillChar(Buffer, SizeOf(Buffer), $00);
end;
end;
procedure TMyData.SetBufferData<T>(const NewData: T);
begin
InitializeBuffer<T>;
BufferAs<T>^ := NewData;
end;
function TMyData.BufferAs<T>: TMyDataHelper<T>.PtrType;
begin
Result := TMyDataHelper<T>.PtrType(@Buffer);
end;
var
Arr: array of TMyData;
SetLength(Arr, ...);
FillChar(Arr[0], Length(Arr)*SizeOf(TMyData), $0);
//...
Arr[Index].InitializeBuffer<TMyData_01>;
populate Arr[Index].BufferAs<TMyData_01>^ fields as needed...
or:
Arr[Index].SetBufferData<TMyData_01>(...);
// and so on ...
var
I: Integer;
begin
for I := Low(Arr) to High(Arr) do
Arr[I].FinalizeBuffer;
end;
很難給出具體的建議。這些問題通常需要算法方法。有時候數據結構設計。有時需要重新設計整個應用。有時候足以讓應用程序能夠識別大地址。也許64位解決了這個問題。我們甚至不知道這個問題。甚至可能是內存碎片。除非你瞭解它們,否則不要試圖解決問題。 –
如果負載與開銷相比非常大,那麼您可能會出錯。 –
我正在查找一個數據容器,只是將INDEX和CLASS_TYPEID和字節傳遞到此存儲區,使用容器中的INDEX回讀數據作爲字節和TYPEID。基於TYPEID我知道如何將這些數據轉換爲正確的數據格式(字符串,INT,Real,dateTime,......)或其他任何有效的解決方案(delphi中針對此問題的任何現代語言功能) – user1769184