保存Word文檔 - 錯誤

Question

我有一些代碼在Word文件中插入多個圖像。一切都很好 直到我試圖保存文件，於是它給出了這樣的錯誤：

An unhandled exception of type 'System.Runtime.InteropServices.COMException' occurred in pdf1.exe

Additional information: This filename is incorrect.

Try one or more of the following:

• Probe the track to make sure it is typed correctly.

• Select a file from the list of files and folders.

，這是代碼：

' first we are creating application of word. 
     Dim WordApp As New Microsoft.Office.Interop.Word.Application() 
     ' now creating new document. 
     WordApp.Documents.Add() 
     ' see word file behind your program 
     WordApp.Visible = True 
     ' get the reference of active document 
     Dim doc As Microsoft.Office.Interop.Word.Document = WordApp.ActiveDocument 
     ' set openfiledialog to select multiple image files 
     Dim ofd As New OpenFileDialog() 
     ofd.Filter = "Images (*.BMP;*.JPG;*.GIF)|*.BMP;*.JPG;*.GIF" 
     ofd.Title = "Select Image To Insert...." 
     ofd.Multiselect = True 
     ' if user select OK, then process for adding images 
     If ofd.ShowDialog() = DialogResult.OK Then 
      ' iterating process for adding all images which is selected by filedialog 
      For Each filename As String In ofd.FileNames 
       ' now add the picture in active document reference 
       doc.InlineShapes.AddPicture(filename, Type.Missing, Type.Missing, Type.Missing) 
      Next 
     End If 
     ' file is saved. 
     doc.SaveAs("‪E:\Doc8.docx", Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, 
    Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, 
    Type.Missing, Type.Missing, Type.Missing, Type.Missing) 
     ' application is now quit. 
     WordApp.Quit(Type.Missing, Type.Missing, Type.Missing) 

Answer 1

難的方法：看來，如果你給文件擴展名爲必須指定文件格式，文件擴展名和擴展名爲fileformat 必須爲匹配：

Option Infer On 
Option Strict On 

Imports Microsoft.Office.Interop 

Public Class Form1 

    Private Sub ProcessWordDocument() 
     Dim WordApp As New Word.Application() 
     WordApp.Documents.Add() 
     WordApp.Visible = True 

     Dim doc = WordApp.ActiveDocument 

     Using ofd As New OpenFileDialog() 
      ofd.Filter = "Images (*.BMP;*.JPG;*.GIF)|*.BMP;*.JPG;*.GIF" 
      ofd.Title = "Select Image To Insert...." 
      ofd.Multiselect = True 

      If ofd.ShowDialog() = DialogResult.OK Then 
       For Each filename As String In ofd.FileNames 
        doc.InlineShapes.AddPicture(filename, Type.Missing, Type.Missing, Type.Missing) 
       Next 

      End If 

     End Using 

     doc.SaveAs("C:\temp\Doc8.docx", FileFormat:=Word.WdSaveFormat.wdFormatDocumentDefault) 
     doc.Close() 

     WordApp.Quit() 

    End Sub 

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
     ProcessWordDocument() 

     ' ensure instance of Word used in ProcessWordDocument is disposed of... 
     GC.Collect() 
     GC.WaitForPendingFinalizers() 
     GC.Collect() 
     GC.WaitForPendingFinalizers() 

    End Sub 

End Class 

其他項目要考慮在該代碼

• 我用格式的named parameter;它恰好使它更明顯地指的是它。
• OpenFileDialog的實例應該調用.Dispose()。 Using構建爲你照顧。
• 你應該確保Word的實例處理得當 - 我使用了The proper way to dispose Excel com object using VB.NET?中顯示的模式。

最簡單的辦法：另一種方法是省略擴展名，並讓Word中選擇它爲您提供：

doc.SaveAs("C:\temp\Doc8") 

所生成的文件 「C：\ TEMP \ Doc8.docx」 被保存。但是您仍然需要使用Using並確保Word實例正確處置，如上所示。