如何測試應用程序（.exe）是否使用運行時包構建

Question

如何在編碼時測試我的.exe Delphi應用程序是使用運行時包還是單一.exe？

Answer 1

另一種可能性：

function UsesRuntimePackages: Boolean; 
begin 
    Result := FindClassHInstance(TObject) <> HInstance; 
end; 

Answer 2

你試過「Islibrary」嗎？

Answer 3

使用可以使用EnumModules()過程中，像這樣：

function EnumModuleProc(HInstance: Integer; Data: Pointer): Boolean; 
begin 
    Result := True; 
    if HInstance <> MainInstance then begin 
    Inc(PInteger(Data)^); 
    Result := False; 
    end; 
end; 

function UsesRuntimePackages: boolean; 
var 
    PckgCount: integer; 
begin 
    PckgCount := 0; 
    EnumModules(EnumModuleProc, @PckgCount); 
    Result := PckgCount > 0; 
end; 

Answer 4

另一種可能性，如果你需要這樣一個外部可執行文件（不運行它）：

procedure InfoProc(const Name: string; NameType: TNameType; Flags: Byte; Param: Pointer); 
begin 
    case NameType of 
    ntContainsUnit: 
     if Name = 'System' then 
     PBoolean(Param)^ := False; 
    end; 
end; 

function UsesRuntimePackages(const ExeName: TFileName): Boolean; 
var 
    Module: HMODULE; 
    Flags: Integer; 
begin 
    Result := True; 

    Module := LoadLibraryEx(PChar(ExeName), 0, LOAD_LIBRARY_AS_DATAFILE); 
    try 
    Flags := 0; 
    GetPackageInfo(Module, @Result, Flags, InfoProc); 
    finally 
    FreeLibrary(Module); 
    end; 
end;