Seq.groupBy：保留原始順序

Question

Dictionary<_,_> -and Seq.groupBy通過伸展出現枚舉元素中的插入順序，然而順序是正式未定義（見this question）。

下面是一些代碼來演示：

let groupByPreservesOrder l = 
    let l2 = 
    l 
    |> Seq.groupBy id 
    |> Seq.map fst 
    |> Seq.toList 
    (l = l2) 

let l = List.init 1000 (fun i -> 
    if i % 2 <> 0 then -(i) else i/2) 

groupByPreservesOrder l //true 

我需要一組功能保證此行爲。什麼是最好的（認真，高效，慣用，...）的方式去做呢？

編輯

下面是做這件事：

let groupByStable f items = 
    let items = items |> Seq.map (fun x -> f x, x) |> Seq.toList 
    let d = items |> Seq.groupBy fst |> dict 
    items 
    |> Seq.distinctBy fst 
    |> Seq.map (fun (k, _) -> k, Seq.map snd d.[k]) 

Answer 1

如果你想確保序列是由每個鍵的首次亮相排序，那麼這裏做到這一點的一種方法：

let groupByOP f s = 
    s 
    |> Seq.mapi (fun i x -> i,x) 
    |> Seq.groupBy (snd >> f) 
    |> Seq.sortBy (snd >> Seq.map fst >> Seq.min) 
    |> Seq.map (fun (k,vs) -> k, vs |> Seq.map snd) 

如果你還想每個組按初始放置排序，那麼我認爲這樣的事情應該工作：

let groupByOP f s = 
    s 
    |> Seq.mapi (fun i x -> i,x) 
    |> Seq.groupBy (snd >> f) 
    |> Seq.map (fun (k,vs) -> k, vs |> Seq.sortBy fst) 
    |> Seq.sortBy (snd >> Seq.head >> fst) 
    |> Seq.map (fun (k,vs) -> k, vs |> Seq.map snd)