Excel單元格值的更改會在另一個單元格中插入「S」

Question

我粘貼了工作表1。注意列。要監視的那個是標題描述和Healthman。一旦在列下發生更改，就會插入一個S。例如，Spectacle Frame更改爲Spec Frame，我們在Change下插入S.更改列是空的。在Healthman下面，當價格變化時，在變更欄中插入一個P.當要刪除產品時，即刪除行時，將在更改下插入X.當插入一行時，因爲我正在與一個隱藏表格單元格進行比較，這就是隱藏表格被更新的原因。我嘗試了以前的代碼，它不工作，並認爲粘貼表單進行審查。
圖例：P =價格漲跌
N = NEW X = DELETED S =說明
代碼變更說明HEALTHMAN

40501  Spectacle Frame    
    40609  Sunglasses    
    40525 S Ready Made Optical    
    41008  Spectacle Case    
    43025 P Transfer - Zyl or Metal Frame 198.00   
    43126 P Transfer - Nylon Supra Frame 314.00   
    43136 P Transfer - Rimless Frame 359.00  

Answer 1

可以使用Worksheet_Change事件。例如參見this和that。 -

示例代碼添加到Workseet A3將自動當你改變另一個細胞如果改變細胞是A1改變，與特定行爲：

Private Sub Worksheet_Change(ByVal Target As Range) 
    If Target.Address = Range("A1").Address Then 
     Range("A3") = "You changed A1" 
    ElseIf Target.Address <> Range("A3").Address Then 'to prevent a change of A3 to trigger an update 
     Range("A3") = "You changed another cell" 
    End If 
End Sub 

Answer 2

雖然與Worksheet_Change工作，你必須確保兩件事。

1）相應的錯誤處理是必須的

2）關閉.EnableEvents以避免無限循環的可能性。

的假設

1）要捕獲更改單元格A1

2）你想在A2顯示 「S」

所以，請更改爲適用於下面的代碼。

CODE

Private Sub Worksheet_Change(ByVal Target As Range) 
    On Error GoTo Whoa 

    If Not Intersect(Target, Range("A1")) Is Nothing Then 
     Application.EnableEvents = False 
     Range("A2").Value = "S" 
    End If 

LetsContinue: 
    Application.EnableEvents = True 
    Exit Sub 
Whoa: 
    MsgBox Err.Description 
    Resume LetsContinue 
End Sub 

隨訪

這是你想什麼呢？

這發生在「ThisWorkbook」代碼區域。

Private Sub Workbook_Open() 
    Dim hiddenSheet As Worksheet 

    Set hiddenSheet = Me.Worksheets.Add 
    hiddenSheet.Visible = xlSheetVeryHidden 

    On Error Resume Next 
    Application.DisplayAlerts = False 
    Sheets("HiddenSheet").Delete 
    Application.DisplayAlerts = True 
    On Error GoTo 0 

    hiddenSheet.Name = "HiddenSheet" 

    Sheet1.Range("A1:D15").Copy hiddenSheet.Range("A1:D15") 
End Sub 

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
    On Error Resume Next 
    Application.DisplayAlerts = False 
    Sheets("HiddenSheet").Delete 
    Application.DisplayAlerts = True 
    On Error GoTo 0 
End Sub 

和這正好在相關工作表區域

Private Sub Worksheet_Change(ByVal Target As Range) 
    On Error GoTo Whoa 

    If Not Intersect(Target, Range("A1:D15")) Is Nothing Then 
     Dim old_value 

     Application.EnableEvents = False 

     old_value = Sheets("HiddenSheet").Range(Target.Address).Value 

     If Target.Value <> old_value Then 
      '~~> Change 1 to whatever offset that you want. 
      Target.Offset(0, 1).Value = "S" 
     End If 
    End If 

LetsContinue: 
    Application.EnableEvents = True 
    Exit Sub 
Whoa: 
    MsgBox Err.Description 
    Resume LetsContinue 
End Sub 

HTH

希德