如何從路徑中提取文件名？

Question

如何在VBA中從C:\Documents\myfile.pdf提取文件名myfile.pdf？

Answer 1

這是從snippets.dzone.com採取：

Function GetFilenameFromPath(ByVal strPath As String) As String 
' Returns the rightmost characters of a string upto but not including the rightmost '\' 
' e.g. 'c:\winnt\win.ini' returns 'win.ini' 

    If Right$(strPath, 1) <> "\" And Len(strPath) > 0 Then 
     GetFilenameFromPath = GetFilenameFromPath(Left$(strPath, Len(strPath) - 1)) + Right$(strPath, 1) 
    End If 
End Function 

Answer 2

嘗試使用分裂函數來獲取從路徑的文件名： MSDN link

Answer 3

在VBA文件和目錄工作的最好辦法Office 2000/2003正在使用腳本庫。添加對Microsoft腳本運行時的引用（IDE中的工具>引用）。

創建一個文件系統對象並使用它執行所有操作。

Dim fso as new FileSystemObject 
Dim fileName As String 
fileName = fso.GetFileName("c:\any path\file.txt") 

FileSystemObject很棒。它提供了很多功能，例如獲取特殊文件夾（我的文檔等），以面向對象的方式創建，移動，複製，刪除文件和目錄。一探究竟。

Answer 4

Dir("C:\Documents\myfile.pdf") 

將返回文件名，但僅當它存在時才返回。

Answer 5

要在Excel宏獲得的文件名是：

filname = Mid(spth, InStrRev(spth, "\", Len(spth)) + 1, Len(spth)) 
MsgBox Mid(filname, 1, InStr(filname, ".") - 1) 

Answer 6

如果你想有一個更強大的解決方案，這將使你倆完整的文件夾的路徑和文件名，在這裏它是：

Dim strFileName As String, strFolderPath As String 
Dim lngIndex As Long 
Dim strPath() As String 

strPath() = Split(OpenArgs, "\") 'Put the Parts of our path into an array 
lngIndex = UBound(strPath) 
strFileName = strPath(lngIndex) 'Get the File Name from our array 
strPath(lngIndex) = ""    'Remove the File Name from our array 
strFolderPath = Join(strPath, "\") 'Rebuild our path from our array 

或者作爲一個子/功能：

Private Sub SeparatePathAndFile(ByRef io_strFolderPath As String, ByRef o_strFileName As String)  
    Dim strPath() As String 
    Dim lngIndex As Long 

    strPath() = Split(io_strFolderPath, "\") 'Put the Parts of our path into an array 
    lngIndex = UBound(strPath) 
    o_strFileName = strPath(lngIndex) 'Get the File Name from our array 
    strPath(lngIndex) = ""    'Remove the File Name from our array 
    io_strFolderPath = Join(strPath, "\")  'Rebuild our path from our array 
End Sub 

您傳遞的完整路徑的第一個參數並將其設置爲文件夾的路徑，而第二個參數將設置爲文件的名稱。

Answer 7

Dim sFilePath$, sFileName$ 
sFileName = Split(sFilePath, "\")(UBound(Split(sFilePath, "\"))) 

Answer 8

這是一個沒有代碼的替代解決方案。這VBA工作在Excel公式欄：

要提取的文件名：

=RIGHT(A1,LEN(A1)-FIND("~",SUBSTITUTE(A1,"\","~",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))) 

要提取的文件路徑：

=MID(A1,1,LEN(A1)-LEN(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1)))) 

Answer 9

我所需要的路徑，而不是文件名。

所以要提取代碼的文件路徑：

JustPath = Left(sFileP, Len(sFileP) - Len(Split(sFileP, "\")(UBound(Split(sFileP, "\"))))) 

Answer 10

我已經通過所有的答案閱讀，我想補充一個，我認爲贏得因爲它的簡單了。與公認的答案不同，這不需要遞歸。它也不需要引用FileSystemObject。

Function FileNameFromPath(strFullPath As String) As String 

    FileNameFromPath = Right(strFullPath, Len(strFullPath) - InStrRev(strFullPath, "\")) 

End Function 

http://vba-tutorial.com/parsing-a-file-string-into-path-filename-and-extension/有這個代碼以及其他功能解析出的文件路徑，擴展名，甚至文件名不帶擴展名。

Answer 11

這是我寫的一個簡單的VBA解決方案，適用於Windows，Unix，Mac和URL路徑。

sFileName = Mid(Mid(sPath, InStrRev(sPath, "/") + 1), InStrRev(sPath, "\") + 1) 

sFolderName = Left(sPath, Len(sPath) - Len(sFileName)) 

您可以使用此代碼測試輸出：

'Visual Basic for Applications 
http = "https://www.server.com/docs/Letter.txt" 
unix = "/home/user/docs/Letter.txt" 
dos = "C:\user\docs\Letter.txt" 
win = "\\Server01\user\docs\Letter.txt" 
blank = "" 

sPath = unix 
sFileName = Mid(Mid(sPath, InStrRev(sPath, "/") + 1), InStrRev(sPath, "\") + 1) 
sFolderName = Left(sPath, Len(sPath) - Len(sFileName)) 

Debug.print "Folder: " & sFolderName & " File: " & sFileName 

另見：Wikipedia - Path (computing)

Answer 12

這從纖細收集@http://archive.atomicmpc.com.au和其他地方：

'since the file name and path were used several times in code 
'variables were made public 

Public FName As Variant, Filename As String, Path As String 

Sub xxx() 
    ... 
    If Not GetFileName = 1 Then Exit Sub ' 
    ... 
End Sub 

Private Function GetFileName() 
    GetFileName = 0 'used for error handling at call point in case user cancels 
    FName = Application.GetOpenFilename("Ramp log file (*.txt), *.txt") 
    If Not VarType(FName) = vbBoolean Then GetFileName = 1 'to assure selection was made 
    Filename = Split(FName, "\")(UBound(Split(FName, "\"))) 'results in file name 
    Path = Left(FName, InStrRev(FName, "\")) 'results in path 
End Function 

Answer 13

Dim nme As String = My.Computer.FileSystem.GetFileInfo(pathFicheiro).Name 
Dim dirc As String = My.Computer.FileSystem.GetFileInfo(nomeFicheiro).Directory 

Answer 14

如果您確定該文件在磁盤上實際存在的最簡單的方法：

Dim fileName, filePath As String 
filePath = "C:\Documents\myfile.pdf" 
fileName = Dir(filePath) 

如果你不能確定文件是否存在，或者只是想提取一個給定的路徑文件名的話，最簡單的方法是：

fileName = Mid(filePath, InStrRev(filePath, "\") + 1)